通达信小心变盘主图指标（其他）指标公式

核心逻辑

这是一个综合型技术指标，主要包含以下几个核心部分： 1. **加权均价计算**：A:=(3*C+L+O+H)/6 是计算一种加权收盘价（收盘价权重最大） 2. **长期均线系统**：X变量计算20日加权移动平均，再通过EMA(X,13)得出"主力成本线" 3. **短期动能指标**：DK:=2*(S2-S6) 计算3日均线与5日均线的差值，用红绿柱状图显示多空动能 4. **均线金叉系统**：通过MA5、MA10、MA30的交叉关系判断趋势反转 5. **超卖反弹信号**：通过AK1、AK指标在21日高低点区间内捕捉反弹机会 整体逻辑是结合长期成本线和短期动能，判断牛熊转换的关键时点。

买卖信号

**买入信号：** - ★红牛：MA10上穿MA5，且MA5>MA30、MA10>MA30、MA10>前一天（均线多头排列后的金叉） - 牛起步：V1（5日EMA）上穿V2（90日EMA*1.01） - ○牛窝：AK1上穿AK（短期超卖区间的反弹信号） - 老鼠仓：满足低价位（低于均价的90%）、涨幅>1.2%、低于5日均线、缩量等多个条件 - ★大胆搏/★加仓：当日涨幅>5%且当天最高价/收盘价<1.01的强势股 **卖出信号：** - ▼逃顶：VAR7（基于6日涨跌幅度比率）下穿82（超买区域） - 小心变盘：连续9日收盘价上涨后出现下跌（变盘预警）

用法

1. **红牛信号出现时积极买入**，代表短期趋势转强 2. **"牛起步"信号是中期行情的启动点**，可作为加仓信号 3. **"牛窝"信号适合超跌反弹操作**，在低位捕捉反弹机会 4. **老鼠仓信号是主力资金悄悄建仓的标志**，但需结合大盘环境判断 5. **"大胆搏"信号出现在强势股中**，可考虑追涨但需严格止损 6. **"逃顶"信号出现时必须离场**，代表短期风险积聚 7. 配合红色柱状线（多头动能）和青色柱状线（空头动能）判断短期方向

公式源码

A:=(3*C+L+O+H)/6;
X:=(20*A+19*REF(A,1)+18*REF(A,2)+17*REF(A,3)+16*REF(A,4)+15*REF(A,5)+
14*REF(A,6)+13*REF(A,7)+12*REF(A,8)+11*REF(A,9)+10*REF(A,10)+9*REF(A,11)+8*REF(A,12)
+7*REF(A,13)+6*REF(A,14)+5*REF(A,15)+4*REF(A,16)+3*REF(A,17)+2*REF(A,18)+
REF(A,20))/210;
RCC:=DYNAINFO(3);
S2:=SMA(C,3,1);
S6:=SMA(C,5,1);
DK:=2*(S2-S6);
STICKLINE(DK>0,RCC,RCC+DK,0,1),COLORRED;
STICKLINE(DK<0,RCC,RCC+DK,0,1),COLORCYAN;
主力成本:EMA(X,13),COLORFF00FF,LINETHICK0;
短期底部:LLV(HIGH,30),LINETHICK2,COLORFFCC00;
IF(MA(C,3),MA(C,3),DRAWNULL),COLORYELLOW,LINETHICK2;
IF(MA(C,9),MA(C,9),DRAWNULL),COLORMAGENTA,LINETHICK2;
IF(MA(C,23.5),MA(C,23.5),DRAWNULL),COLORWHITE;
DRAWKLINE(HIGH,OPEN,LOW,CLOSE);
MA5:=MA(C,5);
MA10:=MA(C,10);
MA30:=MA(C,30);
FA:=BARSLAST(crOSS(MA10,MA5)) AND CROSS(MA5,MA10);
FB:=FA AND MA5>MA30 AND MA10>MA30  AND MA10>REF(MA10,1);
DRAWTEXT(FB,L-0.58,'★红牛'),COLORRED;
V1:=EMA(CLOSE,5);
V2:=EMA(EMA(CLOSE,90)*1.01,10);
DRAWTEXT(CROSS(V1,V2),V1+0.05,'牛起步'),COLOR00FF00;
VAR1:=LLV(LOW,21);
VAR2:=HHV(HIGH,21);
AK1:=EMA((((CLOSE - VAR1) / (VAR2 - VAR1)) * 100),5);
AK:=EMA((((CLOSE - VAR1) / (VAR2 - VAR1)) * 50),13);
AB:=CROSS(AK1,AK);
DRAWTEXT((AB = 1),(LOW * 0.99),'○牛窝'),COLORYELLOW;
AA1:=AMOUNT/V;
BB1:=L<AA1*0.9;
CC1:=(C-REF(C,1))/REF(C,1)*100>1.2;
DD1:=L<MA(C,5)*0.921;
EE1:=V<MA(V,5)*1.5;
老鼠仓:=BB1 AND CC1 AND DD1 AND EE1,LINETHICK0,COLOR0099FF;
DRAWTEXT(老鼠仓,L*0.99,'老鼠仓'),COLOR0099FF;
VAR3AA:=IF((CLOSE>REF(CLOSE,1)),88,0);
VAR4AA:=IF(((CLOSE)/(REF(CLOSE,1))>1.05) AND ((HIGH)/(CLOSE)<1.01) AND (VAR3AA>0),91,0);
DRAWTEXT(FILTER((VAR4AA>90),45),(LOW)*(0.93),'★大胆搏 '),COLOR00FFFF;
DRAWTEXT(FILTER((VAR4AA>90),35),(LOW)*(0.99000001),'★加仓'),COLOR00FFFF;
A1AA:=9;
A2AA:=(REF(CLOSE,A1AA+1)<CLOSE);
DRAWTEXT(FILTER((A2AA>-0.5),84),(HIGH)*(1.05),'小心变盘'),COLORFFFFFF;
VAR6:=REF(C,1);
VAR7:=SMA(MAX(C-VAR6,0),6,1)/SMA(Abs(C-VAR6),6,1)*100;
DRAWTEXT(CROSS(82,VAR7),H*1.01,'▼逃顶'),COLORYELLOW;

通达信黄金彩虹线主图指标（其他）指标公式

核心逻辑

这是一个综合型趋势指标，结合了均线系统、黄金分割和动量信号。 1. **牛线计算**：采用20日加权移动平均（权重从20递减到1），类似EMA但权重不同，用于判断长期趋势方向。 2. **马线**：是牛线的6日简单移动平均，作为牛线的辅助线，用于判断短期趋势。 3. **黄金分割**：基于过去150日的最高价和最低价，计算0.191、0.382、0.5、0.618、0.809五个回撤位，作为支撑/压力参考。 4. **A8指标**：基于价格变动的EMA比率，类似于改进的动量指标，用于捕捉短期超跌反弹机会。

买卖信号

**买入条件**： - A8指标连续2天创新低（LLV(A8,2)=LLV(A8,7)） - 且A8<0持续2天（COUNT(A8<0,2)） - 然后A8上穿其均线（CROSS(A8,MA(A8,2))） - 出现黄色K线（STICKLINE买信号） **卖出条件**：公式中未明确写出卖出条件，需结合均线死叉或价格跌破支撑位自行判断。

用法

1. **趋势判断**：股价在牛线上方运行表示多头趋势，在下方则为空头；牛线向上倾斜看多，向下倾斜看空。 2. **均线金叉死叉**：股价上穿MA5、马线上穿牛线可作为买入参考；反之为卖出信号。 3. **黄金分割支撑**：股价回调到0.382、0.5、0.618等位置可能获得支撑，可考虑分批建仓。 4. **A8买入信号**：当出现黄色K线时，可能是短期超跌反弹的买入点，但需结合整体趋势判断。 5. **RSI辅助**：RSI>

公式源码

MID:=(3*CLOSE+LOW+OPEN+HIGH)/6;
牛线:(20*MID+19*REF(MID,1)+18*REF(MID,2)+17*REF(MID,3)+16
*REF(MID,4)+15*REF(MID,5)+14*REF(MID,6)+13*REF(MID,7)+12*REF(MID,8)+11
*REF(MID,9)+10*REF(MID,10)+9*REF(MID,11)+8*REF(MID,12)+7*REF(MID,13)+6*REF(MID,14)+5
*REF(MID,15)+4*REF(MID,16)+3*REF(MID,17)+2*REF(MID,18)+REF(MID,20))/210,COLORRED;
马线:MA(牛线,6),COLORGREEN;
MAA5:MA(C,5),COLORFF00FF,LINETHICK2;
A3:=(C-LLV(L,9))/(HHV(H,9)-LLV(L,9))*100;
A4:=SMA(A3,3,1);
A5:=SMA(A4,3,1);
A6:=3*A4-2*A5;
A7:=C-REF(C,1);
A8:=100*EMA(EMA(A7,6),6)/EMA(EMA(Abs(A7),6),6);
买:=LLV(A8,2)=LLV(A8,7) AND COUNT(A8<0,2) AND crOSS(A8,MA(A8,2));
STICKLINE(买,OPEN,CLOSE,2,0),COLORYELLOW;
LC:=REF(CLOSE,1);
rsi:=((SMA(MAX((CLOSE - LC),0),3,1) / SMA(ABS((CLOSE - LC)),3,1)) * 100);
FF:=EMA(CLOSE,3);
MA15:=EMA(CLOSE,21);
日:=150;昨前:=3;
高1:=REF(HHV(H,日),昨前);
低1:=REF(LLV(L,日),昨前);
H1:=高1-(高1-低1)*0.191; 
H2:=高1-(高1-低1)*0.382; 
H3:=高1-(高1-低1)*0.5; 
H4:=高1-(高1-低1)*0.618; 
H5:=高1-(高1-低1)*0.809;
顶:REFDATE(高1,DATE),COLORRED;
一0.809:REFDATE(H1,DATE),COLORYELLOW;
二0.618:REFDATE(H2,DATE),COLORMAGENTA;
三0.500:REFDATE(H3,DATE),COLORWHITE;
四0.382:REFDATE(H4,DATE),COLORGREEN;
五0.191:REFDATE(H5,DATE),COLORYELLOW;
低:REFDATE(低1,DATE),COLORRED;

通达信观音点化指标（其他）指标公式

核心逻辑

这是一个综合型市场环境与个股状态监测指标，包含以下几个核心部分： 1. **大盘多空判断**：通过计算大盘指数（以成分股均价模拟）的多空线及其短期波动，判断大盘处于"福缘"（多头）还是"缘尽"（空头）状态。 2. **筹码分布分析**：通过"苦难众生"指标计算当前价格以上被套筹码的比例，数值越高表示套牢盘越多。同时计算"涨X成仍套比"，分析不同涨幅后的套牢比例。 3. **多空对峙位**：分别计算长线（120周期）和短线（30周期）的多空对峙位，通过SMA平滑后形成"J长"和"J短"指标，用于判断趋势方向。 4. **乖离率分析**：计算13日、21日、34日周期的价格乖离率，用于判断超跌和强势程度。

买卖信号

- **买入信号**： - **佛珠**：股价跌破34日均线18.2%以上，或跌破60日均线38.2%以上（大底信号） - **观音指点**：短线多空对峙位上穿前一天，且K短<5（短线买入） - **慈航普渡**：苦难众生指标连续2天低于大盘参数值（超跌反弹） - **虔心向佛**：长线多空对峙位上升（长线多头） - **羽化/飞升/成仙**：乖离率指标满足特定条件（强势信号） - **卖出信号**： - 大盘"缘尽"状态 - 短线多空对峙位下降

用法

1. 首先观察大盘状态，大盘"福缘"时可积极参与，"缘尽"时需谨慎 2. 关注"佛珠"信号出现，可能是历史大底 3. "慈航普渡"出现时表示短期超跌，可能存在反弹机会 4. "观音指点"是短线买入信号 5. 观察乖离率指标，"成仙"信号出现表示强势特征明显 6. 结合"虔心向佛"判断长线趋势方向

公式源码

DRAWGBK(C>0,RGB(000,80,120),RGB(250,250,250),0,0,0);
{大盘状态}
X:=IF(PERIOD=5,2,5);
PLOYLINE(C,X),COLORFFFFFF,LINETHICK3;
P综价:=(INDEXH+INDEXL+INDEXO+3*INDEXC)/6;
P多空线:=(WMA(P综价,2)+WMA(P综价,4)+WMA(P综价,6)+WMA(P综价,8))/4;
P短线多空对峙位:=(P多空线-LLV(P多空线,30))/(HHV(P多空线,30)-LLV(P多空线,30))*10;
PK短:=SMA(P短线多空对峙位,3,1);
PD短:=SMA(PK短,3,1);
PJ短:=3*PK短-2*PD短;
PJ短A:=IF(PJ短>10,10,PJ短);
PJ短B:=IF(PJ短A<0,0,PJ短A);
P均J短B:=SMA(PJ短B,2,1);
大盘福缘:P均J短B>=REF(P均J短B,1),NODRAW;
大盘缘尽:NOT(大盘福缘),NODRAW;
{弱态描述}
苦难众生:EMA((1-WINNER(C)),21)*10,COLOR008800;
金色圣泉:HHV(苦难众生,3)>苦难众生,COLOR0099DD,LINETHICK0;
DRAWBAND(IF(金色圣泉,HHV(苦难众生,3),0),RGB(220,183,35),0,0);
观音湖:IF(苦难众生<X,X,DRAWNULL),COLORFFFFFF,LINETHICK1;
DRAWBAND(IF(观音湖,X,DRAWNULL),RGB(159,159,0),苦难众生,DRAWNULL);
DRAWBAND(IF(苦难众生>0,苦难众生,0),RGB(0,100,50),0,0);
DRAWBAND(IF(苦难众生>9.5,苦难众生,9.5),RGB(255,255,0),IF(苦难众生<9.5,DRAWNULL,苦难众生),0);
涨二成仍套比:=(1-WINNER(1.2*C))*10;
涨二成五仍套比:=(1-WINNER(1.25*C))*10;
涨三成仍套比:=(1-WINNER(1.3*C))*10; 
涨四成仍套比:=(1-WINNER(1.4*C))*10;
涨五成仍套比:=(1-WINNER(1.5*C))*10;
DRAWBAND(涨二成仍套比,RGB(125,255,125),0,0);
DRAWBAND(涨二成五仍套比,RGB(50,255,50),0,0);
DRAWBAND(涨三成仍套比,RGB(0,200,0),0,0);
DRAWBAND(涨四成仍套比,RGB(0,150,0),0,0);
DRAWBAND(涨五成仍套比,RGB(0,100,0),0,0);
{大底判断}
佛珠:(C-MA(C,34))/MA(C,34)<-0.382 OR C/MA(C,60)<0.618,COLORRED,LINETHICK0;
{长线波动与短线波动的描述}
综价:=(H+L+O+3*C)/6;
多空线:=(WMA(综价,2)+WMA(综价,4)+WMA(综价,8)+WMA(综价,16))/4;
长线多空对峙位:=(多空线-LLV(多空线,120))/(HHV(多空线,120)-LLV(多空线,120))*10;
K长:=SMA(长线多空对峙位,21,1);
D长:=SMA(K长,21,1);
J长:=3*K长-2*D长;
J长A:=IF(J长>10,10,J长);
J长B:=IF(J长A<0,0,J长A);
均J长B:=SMA(J长B,2,1);
虔心向佛:均J长B>=REF(均J长B,1),COLORFF63DB,LINETHICK0;
短线多空对峙位:=(多空线-LLV(多空线,30))/(HHV(多空线,30)-LLV(多空线,30))*10;
K短:=SMA(短线多空对峙位,3,1);
D短:=SMA(K短,3,1);
J短:=3*K短-2*D短;
J短A:=IF(J短>10,10,J短);
J短B:=IF(J短A<0,0,J短A);
均J短B:=SMA(J短B,2,1);
观音指点:crOSS(均J短B,REF(均J短B,1)) AND K短<5,COLORYELLOW,LINETHICK0;
慈航普渡:FILTER(苦难众生<X AND COUNT(苦难众生<X,2)=1,5);
{强势描述}
N1:=IF(PERIOD=5,13,IF(PERIOD=6,4,2));
N2:=IF(PERIOD=5,21,IF(PERIOD=6,6,3));
N3:=IF(PERIOD=5,34,IF(PERIOD=6,8,4));
乖离13:=10-WMA((C-MA(C,N1))/MA(C,N1),5)*10;
乖离21:=10-WMA((C-MA(C,N2))/MA(C,N2),5)*10;
乖离34:=10-WMA((C-MA(C,N3))/MA(C,N3),5)*10;
可羽化:=乖离13<10;
羽化:可羽化 AND 乖离13<REF(乖离13,1),LINETHICK0,COLORFF76FF;
可飞升:=乖离21<10;
飞升:可飞升 AND 乖离21<REF(乖离21,1) AND 乖离21<乖离13,LINETHICK0,COLOR00389A;
可成仙:=乖离34<10;
成仙:乖离34<REF(乖离34,1) AND 可成仙 AND 乖离34<乖离21,LINETHICK0,COLOR00BEFF;
DRAWBAND(10,RGB(230,230,0),IF(可成仙,乖离34,10),0);
DRAWBAND(10,RGB(200,200,0),IF(成仙,乖离34,10),0);
DRAWBAND(10,RGB(128,0,64),IF(可飞升,乖离21,10),0);
DRAWBAND(10,RGB(255,128,255),IF(可羽化,乖离13,10),0);
{画图}
DRAWICON(佛珠,1.5,13);
IF(虔心向佛,均J长B,DRAWNULL),COLOR990099,LINETHICK2,DOTLINE;
IF(NOT(虔心向佛),均J长B,DRAWNULL),COLOR888888,LINETHICK2,DOTLINE;
福缘:IF(均J短B>=REF(均J短B,1),均J短B,DRAWNULL),COLOR0000C8,LINETHICK3;
缘尽:IF(均J短B<=REF(均J短B,1),均J短B,DRAWNULL),COLORFFFFFF,LINETHICK3;
DRAWICON(观音指点,REF(均J短B,1)+0.5,11);
DRAWTEXT(慈航普渡,X+1,'慈航普渡'),COLOR0000FF;
IF(大盘福缘,P均J短B,DRAWNULL),COLOR0033FF,CIRCLEDOT;
IF(大盘缘尽,P均J短B,DRAWNULL),COLORCCCCCC,CIRCLEDOT;
{PLOYLINE(大盘缘尽 AND 福缘,均J短B),COLORMAGENTA,LINETHICK2;};

通达信小邪四区主图指标（其他）指标公式

核心逻辑

这是一个综合型技术指标，主要包含三个部分： 1. **空间框架**：以120天为周期，计算该周期内的最高价和最低价，形成震荡区间。然后在区间内画出平衡线（50%位置）、压力线（80.9%位置）和支撑线（19.1%位置），类似于江恩角度线的思想，用于判断股价在区间中的相对位置。 2. **趋势判断**：使用14日（A1）和25日（A2）两条指数移动平均线，通过计算它们的当日变化率（A1X、A2X）来判断多空趋势。当A1X>=0时表示短期多头，占据主导。 3. **布林带辅助**：附加了26日布林带（boll±2倍标准差）作为辅助参考。

买卖信号

**买入信号**： - A1X>=0，且之前A1X从负转正（金叉）的条件成立时，显示"买入持股"信号（洋红色线条） **卖出信号**： - A1X<0，且之前A1X从正转负（死叉）的条件成立时，显示"卖出空仓"青色线条 **看多**：A1X>=0时，红色显示做多 **看空**：A1X<0且A2X<0时，绿色显示看空

用法

1. **判断相对位置**：观察股价处于压力线、支撑线还是平衡线附近，辅助判断是否超买超卖 2. **趋势跟随**：当出现红色"做

公式源码

M:=120;
大盘指数:INDEXC,NODRAW,COLORLIMAGENTA ;
大盘指数涨跌:(大盘指数-REF(大盘指数,1)),NODRAW;
涨家数:INDEXADV,NODRAW,COLORLIMAGENTA ;
跌家数:INDEXDEC,NODRAW,COLORGREEN;
T:=120;{设置天数}
K:=BARSLAST(CURRBARSCOUNT=T);
GD:=CONST(IF(ISLASTBAR=1,HHV(H,K),0));
DD:=CONST(IF(ISLASTBAR=1,LLV(L,K),0));
KJ:=GD-DD;
GD4:=IF(CURRBARSCOUNT<=T/2,GD,DRAWNULL);
DRAWBAND(GD4,RGB(0,0,250),DD+KJ/2,RGB(0,0,0));{该行设置背景色}
平衡:IF(CURRBARSCOUNT<=T,DD+KJ/2,DRAWNULL),COLOR00FFFF,NODRAW;
压力:IF(CURRBARSCOUNT<=T,GD-KJ*0.191,DRAWNULL),COLORFF00FF,NODRAW;
支撑:IF(CURRBARSCOUNT<=T,DD+KJ*0.191,DRAWNULL),COLOR00FF00,NODRAW;
天:BARSLAST(L=DD),COLOR00FFFF,NODRAW;
高:IF(CURRBARSCOUNT<=T,GD,DRAWNULL),COLORGREEN,POINTDOT;
低:IF(CURRBARSCOUNT<=T,DD,DRAWNULL),COLORRED,POINTDOT;
STICKLINE(CURRBARSCOUNT=T,GD,DD,0,-1),COLORGREEN;
STICKLINE(CURRBARSCOUNT=T/2,GD,DD,0,-1),COLORGREEN;
STICKLINE(CURRBARSCOUNT=1,GD,DD,0,-1),COLORGREEN;
STICKLINE(CURRBARSCOUNT<=T,平衡,平衡,3,-1),COLORWHITE;
STICKLINE(CURRBARSCOUNT<=T/2,压力,压力,3,-1),COLORRED;
STICKLINE(CURRBARSCOUNT<=T/2,支撑,支撑,3,-1),COLORGREEN;
DRAWKLINE(HIGH,OPEN,LOW,CLOSE);
DRAWTEXT(CURRBARSCOUNT=1,压力,'0.809'),COLOR0000FF;
DRAWTEXT(CURRBARSCOUNT=1,平衡,'0.500'),COLORFFFFFF;
DRAWTEXT(CURRBARSCOUNT=1,支撑,'0.191'),COLOR00FFFF;
DRAWTEXT(CURRBARSCOUNT=T/2+9,GD-KJ/12,'★强势区域--急拉减仓!'),COLOR00FFFF;
DRAWTEXT(CURRBARSCOUNT=T/2+9,GD-KJ/3,'●震荡整理--寻机低吸!'),COLOR00FF00;
DRAWTEXT(CURRBARSCOUNT=T/2+9,DD+KJ/3,'◆反弹中轨--逢高休息!'),COLORFFFFFF;
DRAWTEXT(CURRBARSCOUNT=T/2+9,DD+KJ/10,'■弱势区域--暂不参与!'),COLORFFFF00;
DRAWTEXT_FIX(1,0.00,0,0,'■ 目前k线天数：')COLORWHITE;
DRAWTEXT_FIX(1,0.12,0,0,'120天!')COLORWHITE;
DRAWTEXT_FIX(1,0.00,0.04,0,'■ 建议查阅K线：')COLORWHITE;
DRAWTEXT_FIX(1,0.12,0.04,0,'短线30天,中长线120天!')COLORWHITE;
VC:=((CLOSE-MA(CLOSE,6))/MA(CLOSE,6)*100+(CLOSE-MA(CLOSE,24))/MA(CLOSE,24)*100+(CLOSE-MA (CLOSE,32))/MA(CLOSE,32)*100)/3;
S2:=IF(VC>20 AND FILTER(VC< REF(VC,1),5),H+0.02,DRAWNULL),CIRCLEDOT,LINETHICK3,COLORGREEN;
A0:=(L+H+C*2)/4;
A1:EMA(A0,14),NODRAW;
A2:=EMA(A0,25),NODRAW;
A1X:=(A1-REF(A1,1))/REF(A1,1)*100,NODRAW;
A2X:=(A2-REF(A2,1))/REF(A2,1)*100,NODRAW;
买入持股:IF(A1X>=0 AND BARSLAST(crOSS(A1X,0))>0,REF((C+O)/2,BARSLAST(CROSS(A1X,0))),DRAWNULL),COLORMAGENTA,LINETHICK2;
卖出空仓:IF(A1X<0 AND BARSLAST(CROSS(0,A1X))>0,REF((C+O)/2,BARSLAST(CROSS(0,A1X))),DRAWNULL),COLORCYAN,LINETHICK2;
做多:IF(A1X>=0,A1,DRAWNULL)COLORRED,LINETHICK2;
看空:IF(A1X<0 AND A2X<0,A1,DRAWNULL)COLORGREEN,LINETHICK2;
{STICKLINE(C<O,LOW,HIGH,0,1),COLOR00FF00;}{绿色上下影线}
STICKLINE(C<O,O,C,3,0),COLOR007700;{绿色}
STICKLINE(C<O,O,C,2,0),COLOR00AA00;
STICKLINE(C<O,O,C,1.2,0),COLOR00DD00;
STICKLINE(C<O,O,C,0.2,0),COLOR00FF00;
STICKLINE(C>O,O,C,3,0),COLOR000099;{红色}
STICKLINE(C>O,O,C,2,0),COLOR0000BB;
STICKLINE(C>O,O,C,1.3,0),COLOR0000DD;
STICKLINE(C>O,O,C,0.3,0),COLOR0000FF;
VAR1:=MA(CLOSE,5);
boll:MA(C,26),COLORYELLOW,POINTDOT;
UB:BOLL+2*STD(VAR1,26),COLORGREEN,CROSSDOT;
LB:BOLL-2*STD(VAR1,26),COLORRED,CROSSDOT;

通达信小小主图指标（趋势型）指标公式

核心逻辑

这是一个综合型趋势追踪指标，结合了价格位置、成交量加权均价、波动率通道和动量分析。 **计算原理：** 1. **加权价格ZAX**：采用（5×收盘价+2×最低价+2×最高价+开盘价）/10的综合价格，比普通均价更敏感 2. **成交量加权均价MN**：将成交量与价格结合计算真实市场成本 3. **布林类通道（DK、BOLS、UB、LB）**：基于价格波动率计算的动态支撑压力位 4. **动力指标（DLX）**：衡量价格在近期高低区间的相对位置变化 5. **多均线系统**：MAA（8日）、MAA1（10日）、MAA2（20日）构成短期、中期均线组合 **用途**：识别趋势方向、捕捉回调后的起涨点、判断超卖反弹机会

买卖信号

**买入信号：** 1. **图标信号**：DK上穿UP上轨 且 DLX上升 且 收盘价>MA均线 → 买入图标22 2. **阴买信号（XG1AS）**：需同时满足以下条件： - JS：前三日最高价=10日最高 且 ZAX<昨日ZAX 且 ZAX<MAA1 且 ZAX>MAA2 且 MAA1>MAA2 且 开盘价<MAA1 且 最高价<MAA1 且 最低价>MAA2（回调到均线粘合处） - ZB：BIAS1<-3% 且 WR2>85 且 ZAX<昨日ZAX 且 最低价<昨日最低价（超卖） - EZTO：10日内存在涨停股

用法

1. **趋势判断**：ZAX在MN上方显示粉红色（NO），在下方显示蓝色（NB），红色粗线（BOAL）为均价趋势线 2. **主买入点**：当出现买入图标22时，是较强的突破信号，可考虑买入 3. **阴买模式**：当出现"阴买"文字提示时，是多重条件共振的买点，要求股票前期有涨停、当前超卖、且回调到均线支撑位 4. **结合使用**：建议两个信号相互验证，提高买入可靠性 5. **仓位管理**：出现信号后可分批建仓，跌破均线支撑需考虑止损

公式源码

ZAX:=(5*C+2*L+2*H+O)/10;
VARA2:=LLV(LOW,10);
VARA3:=HHV(HIGH,21);
DLX:=EMA((ZAX-VARA2)/(VARA3-VARA2)*4,4);
INE:=DLX>=REF(DLX,1);
N:=IF(BARSCOUNT(C)>=8,8,BARSCOUNT(C));
AMOV:=vol*ZAX;
MN:=SUM(AMOV,N)/SUM(VOL,N);
MAA:MA(ZAX,8),LINETHICK2,COLORBLUE;
NO:IF(ZAX>=MN,MAA,DRAWNULL),LINETHICK2,COLORMAGENTA;
NB:IF(ZAX<=MN,MAA,DRAWNULL),LINETHICK2,COLORBLUE;
BOAL:EMA(EMA(MN,13),13),COLORRED,LINETHICK2;
AQ:=MIN(OPEN,REF(CLOSE,1));
AW:=MAX(OPEN,REF(CLOSE,1));
MTRQ:=MAX(MAX((HIGH-LOW),Abs(REF(CLOSE,1)-HIGH)),ABS(REF(CLOSE,1)-LOW));
DFQ:=((HIGH-AQ)+(CLOSE-MIN(LOW,REF(CLOSE,1))))/MTRQ;
KF:=((AW-L)+(MAX(HIGH,REF(CLOSE,1))-CLOSE))/MTRQ;
DK:=DFQ/KF;{WWW.GOODGUPIAO.COM}
BOLS:=MA(DK,20);
UB:=BOLS+2*STD(DK,20);
LB:=BOLS-2*STD(DK,20);
BLQ:=MA(DK,12);
RW:=POW(DK-BLQ,2);
X:=SQRT(MA(RW,12));
UP:=0.5*(BLQ+2.5*X)+0.5*UB;
DP:=0.5*(BLQ-2.5*X)+0.5*LB;
DRAWICON(FILTER(crOSS(DK,UP) AND INE AND C>MAA,5),L*0.99,22);
EZT:=(HIGH>=ZTPRICE(REF(CLOSE,1),0.1));
EZTO:=EXIST(EZT,10);
MAA1:=MA(ZAX,10);
MAA2:=MA(ZAX,20);
JS:=REF(H,3)=HHV(H,10) AND ZAX<REF(ZAX,1) AND ZAX<MAA1 AND ZAX>MAA2 AND MAA1>MAA2 AND O<MAA1 AND H<MAA1 AND L>MAA2;
wr2:=100*(HHV(HIGH,6)-CLOSE)/(HHV(HIGH,6)-LLV(LOW,6));
bias1 :=(ZAX-MA(ZAX,6))/MA(ZAX,6)*100;
ZB:=BIAS1<-3 AND WR2>85 AND ZAX<REF(ZAX,1) AND L<REF(L,1);
XG1AS:=JS AND ZB AND EZTO;
DRAWTEXT(XG1AS,L*0.96,'阴买'),COLORRED;

通达信小小抄底选股指标（超买超卖型）指标公式

核心逻辑

该指标通过计算当前收盘价与40日均线的偏离程度（SX），来寻找超跌反弹的买入机会。SX表示当前价格相对40日均线的跌幅百分比，当SX值在-25%到-30%之间时，认为价格已经进入超跌区域，可能出现反弹。

买卖信号

**买入条件（小抄底信号）：** 1. 前一天SX值小于前两天（SX在下降），且当前SX在-25%至-30%之间，同时SX开始反弹（大于等于前一天） 2. 或者前一天SX从下方穿越-25%，今天SX也上穿-25% **卖出条件：**无明确卖出条件

用法

1. 当出现“小小抄底”信号时，表示价格可能已经超跌，可以考虑分批建仓 2. 该指标属于左侧交易策略，尝试在价格反弹前买入 3. 建议结合其他技术指标（如成交量、RSI等）进行验证，提高信号可靠性 4. 由于是抄底策略，需要做好止损设置

公式源码

AN:=(C,25);
AB:=(C,40);
SX:=(CLOSE-MA(CLOSE,40))/MA(CLOSE,40)*100 ;
CC:=((REF(SX,1)<REF(SX,2)  AND SX<-25 AND SX>-30) AND 
SX>=REF(SX,1)) OR (REF(crOSS(-25,SX),1) AND CROSS(SX,-25));
小小抄底:CC,COLORFFBB00;

通达信小仙均线主图指标（趋势型）指标公式

核心逻辑

该指标是一个基于MACD指标改进的趋势追踪工具。主要原理是： 1. **利用MACD的金叉死叉确定波段转折点**：通过MACD的DIF与DEA交叉来识别价格的阶段性高低点 2. **计算关键价位**：根据MACD交叉后的周期数，定位最近的高点和低点位置 3. **绘制趋势线**：在MACD多头时（红柱）连接高点形成压力线，在MACD空头时（绿柱）连接低点形成支撑线 4. **动态压力支撑**：计算21日周期的最高价和最低价作为短期压力/支撑位，当价格突破压力位时变色提示

买卖信号

- **MACD金叉**：DIF上穿DEA，可能产生买入信号 - **MACD死叉**：DIF下穿DEA，可能产生卖出信号 - **趋势线突破**：价格向上突破红色压力线可能买入，向下跌破绿色支撑线可能卖出 - **压力位突破**：价格突破21日高点时，压力线变红表示可能进入强势阶段

用法

1. 观察MACD的金叉死叉作为趋势转换的参考 2. 红色趋势线代表短期压力位，绿色趋势线代表短期支撑位 3. 当价格站上红色压力线且MACD红柱时，考虑买入 4. 当价格跌破绿色支撑线且MACD绿柱时，考虑卖出 5. 配合21日均线支撑/压力位使用，效果更佳

公式源码

F:=macd.DIF;
D:=MACD.DEA;
M:=MACD.MACD;
HT:=BARSLAST(crOSS(F,D));
HT1:=SUMBARS(HT=0,2);
LT:=BARSLAST(CROSS(D,F));
LT1:=SUMBARS(LT=0,2);
H1:=BARSLAST(H=HHV(H,HT+1));
H2:=REF(H1,LT)+CONST(LT);
H3:=REF(H1,LT1-1)+CONST(LT1);
L1:=BARSLAST(L=LLV(L,LT+1));
L2:=REF(L1,HT1-1)+CONST(HT1);
L3:=REF(L1,HT)+CONST(HT);
DRAWLINE(CURRBARSCOUNT=CONST(H2)+1,H,CONST(M)>0 AND CURRBARSCOUNT=CONST(H1)+1,H,1),COLORRED;
DRAWLINE(CURRBARSCOUNT=CONST(L2),L,CONST(M)>0 AND CURRBARSCOUNT=CONST(L1)+1,L,1),COLORYELLOW;
DRAWLINE(CURRBARSCOUNT=CONST(H3),H,CONST(M)<0 AND CURRBARSCOUNT=CONST(H1)+1,H,1),COLORRED;
DRAWLINE(CURRBARSCOUNT=CONST(L3)+1,L,CONST(M)<0 AND CURRBARSCOUNT=CONST(L1)+1,L,1),COLORYELLOW;
N1:=1;
AX:=REF(H,N1)=HHV(H,2*N1+1);
B1:=FILTER(AX,N1);
C1:=BACKSET(B1,N1+1);
D1:=FILTER(C1,N1);{高点}
A2X:=REF(L,N1)=LLV(L,2*N1+1);
B2:=FILTER(A2X,N1);
C2:=BACKSET(B2,N1+1);
D2:=FILTER(C2,N1);{低点}
E1:=(REF(LLV(L,2*N1),1)+REF(HHV(H,2*N1),1))/2; E2:=(H+L)/2;{高低点出现在同一k线上时可作取舍}
H11:=(D1 AND NOT(D2 AND E1>=E2)) OR ISLASTBAR OR BARSCOUNT(C)=1;
L11:=(D2 AND NOT(D1 AND E1<E2)); H21:=D1 AND NOT(D2 AND E1>=E2);
X1:=REF(BARSLAST(H11),1)+1; F1:=BACKSET(H11 AND COUNT(L11,X1)>0,LLVBARS
(IF(L11,L,10000),X1));
G1:=F1>REF(F1,1); I1:=BACKSET(G1,2); LD:=I1>REF(I1,1);{过滤后低点}
L21:=LD OR ISLASTBAR OR BARSCOUNT(C)=1;
X2:=REF(BARSLAST(L21),1)+1; F2:=BACKSET(L21 AND COUNT(H21,X2)>0,HHVBARS
(IF(H21,H,0),X2));
G2:=F2>REF(F2,1); I2:=BACKSET(G2,2); HD:=I2>REF(I2,1);{过滤后高点}
R1:=BACKSET(ISLASTBAR,BARSLAST(HD)+1); S1:=R1>REF(R1,1); {前一高}
T1:=BACKSET(ISLASTBAR,BARSLAST(LD)+1); U1:=T1>REF(T1,1); {前一低}
R2:=BACKSET(S1,REF(BARSLAST(HD),1)+2); S2:=R2>REF(R2,1); {前二高}
T2:=BACKSET(U1,REF(BARSLAST(LD),1)+2); U2:=T2>REF(T2,1); {前二低}
T3:=BACKSET(U2,REF(BARSLAST(LD),1)+2); U3:=T3>REF(T3,1); {前三低}
T4:=BACKSET(U3,REF(BARSLAST(LD),1)+2); U4:=T4>REF(T4,1); {前四低}
R3:=BACKSET(S2,REF(BARSLAST(HD),1)+2); S3:=R3>REF(R3,1); {前三高}
R4:=BACKSET(S3,REF(BARSLAST(HD),1)+2); S4:=R4>REF(R4,1); {前四高}
短期压力:DRAWLINE(S2,H,S1,H,1),COLORRED;
短期支撑:DRAWLINE(U2,L,U1,L,1),COLORGREEN;
A77:=(2*C+H+L)/4;
支撑:LLV(A77,21),COLORMAGENTA,DOTLINE;
压力:HHV(A77,21),COLORGREEN,DOTLINE;
IF(C>压力 OR 压力>REF(压力,1),压力,DRAWNULL),COLORRED,LINETHICK1;
DRAWTEXT(ISLASTBAR,压力,'压力'),COLORGREEN;
DRAWTEXT(ISLASTBAR,支撑,'支撑'),COLORMAGENTA;

通达信小天多空主图指标（其他）指标公式

核心逻辑

这是一个综合型技术指标，包含三个主要分析维度： 1. **相对强弱分析（A变量）**：计算个股涨跌幅与指数涨跌幅的差值，反映个股相对于大盘的强弱程度。 2. **能量潮分析（HSNP系列）**：基于改良型OBV思想，统计90日内上涨日的涨幅总和与下跌日的跌幅总和的比值，衡量市场做多与做空的能量对比。 3. **趋势判断（SK/SD/SP和A1/B1）**：采用类似MACD的双均线系统，通过不同周期EMA的差值判断短期和中期趋势方向。

买卖信号

- **A变量**：红线在零轴上方表示个股强于大盘 - **长线1与长线2**：快线在慢线上方为多头信号 - **做多与做空**：红线表示多头主导，绿线表示空头主导 **买入参考**：A>0、红线（做多）向上突破、做多信号出现 **卖出参考**：A<0、绿线（做空）向下、做空信号出现

用法

1. 综合观察多个信号的一致性，多个指标同时发出买入信号时可靠性更高 2. A变量可作为个股与大盘相对强弱的参考 3. 长线指标用于判断中长期趋势方向 4. 做多/做空信号用于把握短期操作方向

公式源码

A:EMA((CLOSE-ref(c,1))/ref(c,1)*10-
(INDEXC-ref(INDEXC,1))/ref(INDEXC,1)*10,5),COLORRED;
STICKLINE(A>0,0,A,1,2),LINETHICK1,COLORRED;
STICKLINE(A<0,0,A,1,2),LINETHICK2,COLORGREEN;
HSNP1:=CLOSE-REF(CLOSE,1);
HSNP2:=IF(CLOSE-REF(CLOSE,1)>=0,HSNP1,0);
HSNP3:=REF(CLOSE,1)-CLOSE;
HSNP4:=IF(CLOSE-REF(CLOSE,1)<=0,HSNP3,0);
HSNP5:=SUM(HSNP2,90)/SUM(HSNP4,90);
HSNP6:=100-100/(1+HSNP5);
HSNP7:=EMA(HSNP6,21);
HSNP8:=EMA(HSNP7,5);
HSNP:=EMA(HSNP7,3);
np:= (HSNP7-HSNP),,linethick1;
nl:=(HSNP-HSNP7),COLORYELLOW,linethick1;
STICKLINE(nl<0,0,nl,1,2),Color0B0B77;
STICKLINE(np<0,0,np,1,2),COLOR666666;
JJ :=(C*2+H+L)/4;
SK := EMA(JJ,13) - EMA(JJ,21);
SD := EMA(SK,3);
SP := EMA(SK,10);
长线1:IF(SD>=SP,SD,SP),LINETHICK2,;
长线2:IF(SP-SD,SP,SD),LINETHICK2,COLORWHITE;
A1:=EMA(CLOSE,7)-EMA(CLOSE,21);
B1:=EMA((0.668*REF(A1,1)+0.333*A1),1);
做多:IF(A1>=B1,A1,B1),LINETHICK2,COLORRED;
做空:IF(B1-A1,B1,A1),LINETHICK2,COLORGREEn;

通达信小碎阴反转选股指标（超买超卖型）指标公式

核心逻辑

该指标旨在捕捉超跌反弹的短线机会。其核心逻辑是：要求股价前期已经连续下跌或连续收阴线（至少3天），然后在今天出现反转信号——今天开盘价低于昨天的最低价，但收盘价不低于3天前的最高价，形成一种“先抑后扬”的走势。同时要求收盘价位于80日均线上方，以确保中长期趋势未破。

买卖信号

**买入条件（XG信号）**：满足以下全部条件时产生选股信号： 1. 昨天之前连续3天收盘价下跌（VAR5），或昨天之前连续3天收阴线（VAR6） 2. 今天收盘价≥3天前的最高价（VAR3） 3. 今天开盘价≤昨天的最低价（VAR4） 4. 收盘价在80日EMA均线之上（VAR11） 5. 昨天之前连续3天收阴线（VAR14） **卖出信号**：无明确卖出条件，该指标主要用于选股。

用法

1. **选股使用**：该指标主要用于筛选符合条件的股票，可作为选股公式使用 2. **结合其他分析**：建议结合成交量、大盘环境、板块热点等因素综合判断 3. **仓位控制**：超跌反弹属于短线策略，应注意仓位管理 4. **止损建议**：如果买入后股价跌破80日均线，应考虑止损

公式源码

VAR1:=DOWNNDAY(C,3);
VAR2:=EVERY(O>C,3);
VAR3:=C>=REF(MAX(C,O),3);
VAR4:=O<=REF(MIN(C,O),1);
VAR5:=REF(VAR1,1);
VAR6:=REF(VAR2,1);
VAR8:=VAR3 AND VAR4 AND VAR5;
VAR9:=VAR3 AND VAR4 AND VAR6;
VAR10:=EMA(CLOSE,80);
VAR11:=C>VAR10;
VAR12:=VAR9 OR VAR8 AND VAR11;
VAR13:=COUNT(CLOSE<OPEN,3)=3;
VAR14:=REF(VAR13,1);
XG:VAR12 AND VAR14;

通达信小松买入指标（均线型）指标公式

核心逻辑

该指标由两部分组成： 1. **VARA和VARC**：计算收盘价5日变化率与20日变化率的比值，用于判断价格动量的相对强弱。当VARA>0表示短期动量向上，若VARC下穿VARA则意味着短期动量开始转弱。 2. **买线和卖线**：买线是2日EMA（短期均线），卖线是基于21日均线斜率计算的42日EMA（类似动态压力线）。两者交叉代表短期价格上穿/下穿中期趋势通道。

买卖信号

- **买入**：买线从下向上突破卖线（买线 CROSS 卖线） - **卖出**：VARA>0 且 VARC从下向上穿越VARA（动量转弱信号），显示90；其他情况显示100

用法

1. 当买线从下向上穿越卖线时，形成买入信号，表明短期趋势向上突破中期压力 2. 当VARA>0且VARC上穿VARA时，形成卖出信号，表明短期动量开始衰竭 3. 可结合其他指标或均线系统辅助判断，提高信号可靠性

公式源码

VAR9:=CLOSE-REF(CLOSE,5); 
VARA:=EMA(EMA(VAR9,5),5)/EMA(EMA(Abs(VAR9),5),5); 
VARC:=EMA(EMA(VAR9,20),20)/EMA(EMA(ABS(VAR9),20),20); 
卖出:=IF(VARA>0 AND crOSS(VARC,VARA),90,100); 
买线:=EMA(CLOSE,2); 
卖线:=EMA(SLOPE(CLOSE,21)*20+CLOSE,42); 
买入:CROSS(买线,卖线);

通达信小松看盘主图指标（其他）指标公式

核心逻辑

该指标是一个综合型技术分析指标，主要包含三个子系统： 1. **散户庄家指标**：通过计算短期价格波动与近期高低点的关系，模拟市场中的散户和庄家行为。散户线波动较剧烈，庄家线较为平滑，两者交叉可判断主力动向。 2. **价格变动率指标**：通过计算近期涨跌与平均波动幅度的比值，判断价格变动速度是否过快，类似于动量指标。 3. **双均线系统**：使用14日(A1)和25日(A2)两条指数均线，通过均线的金叉死叉和相对位置判断趋势方向，并配合RSI和VC指标进行辅助验证。 整体逻辑是结合趋势判断、动量分析和超买超卖综合得出买卖信号。

买卖信号

- **低吸**：散户线上穿庄家线，且散户值<30（图中显示"←低吸"） - **高抛**：庄家线上穿散户线，且散户值>70（图中显示"←高抛"） - **卖出**：VARA>0时，VARC上穿VARA（动量减弱） - **买线信号**：买线上穿卖线（短期均线上穿长期均线） - **RSI信号**：RSI上穿80且*30（超买信号） - **VC信号**：VC>20且开始回落（波动率过高） - **均线金叉**：A1上穿A2或A1X由负转正（上涨趋势） - **均线死叉**：A1下穿A2或A1X由正转负（下跌趋势）

用法

1. **主要信号**：关注散户庄家交叉信号作为主要买卖点，低于30考虑买入，高于70考虑卖出 2. **趋势确认**：观察A1和A2均线的方向和位置关系，红色粗线（持股）表示上升趋势持有，绿色粗线（空仓）表示下降趋势观望 3. **

公式源码

EMA13:=EMA(C,13),COLORWHITE;
EMA21:=EMA(C,21),COLORYELLOW;
EMA34:=EMA(C,34),COLORFF00FF;
EMA60:=MA(C,60),COLORFFCC66;
VAR2:=(2*CLOSE+HIGH+LOW)/4;
VAR3:=IF(YEAR>=2099 AND MONTH>2,0,1);
VAR4:=LLV(LOW,5); VAR5:=HHV(HIGH,4);
散户:=EMA((VAR2-VAR4)/(VAR5-VAR4)*100,4)*VAR3;
庄家:=EMA(0.667*REF(散户,1)+0.333*散户,2)*VAR3;
DRAWTEXT(crOSS(散户,庄家) AND 散户<30,L-0.05,'←低吸'),COLORLIRED;
DRAWTEXT(CROSS(庄家,散户) AND 散户>70,H+0.05,'←高抛'),COLORGREEN;
DRAWICON(CROSS(散户,庄家) AND 散户<30,L-0.05,1);
DRAWICON(CROSS(庄家,散户) AND 散户>70,H+0.05,2);
VAR9:=CLOSE-REF(CLOSE,5);
VARA:=EMA(EMA(VAR9,5),5)/EMA(EMA(Abs(VAR9),5),5);
VARC:=EMA(EMA(VAR9,20),20)/EMA(EMA(ABS(VAR9),20),20);
卖出:=IF(VARA>0 AND CROSS(VARC,VARA),90,100);
DRAWICON(卖出<0,H+0.05,2); 买线:=EMA(CLOSE,2);
卖线:=EMA(SLOPE(CLOSE,21)*20+CLOSE,42);
B1:IF(CROSS(买线,卖线),L-0.02,DRAWNULL),CROSSDOT,LINETHICK3,COLORMAGENTA;
S1:IF(CROSS(80,rsi)*30,H+0.02,DRAWNULL),CROSSDOT,LINETHICK3,COLORYELLOW;
VC:=((CLOSE-MA(CLOSE,6))/MA(CLOSE,6)*100+(CLOSE-MA(CLOSE,24))/MA(CLOSE,24)*100+(CLOSE-MA (CLOSE,32))/MA(CLOSE,32)*100)/3;
S2:=IF(VC>20 AND FILTER(VC< REF(VC,1),5),H+0.02,DRAWNULL),CIRCLEDOT,LINETHICK3,COLORGREEN;
A0:=(L+H+C*2)/4;
A1:EMA(A0,14)COLORBLUE,LINETHICK2;
A2:=EMA(A0,25)COLORLIBLUE,LINETHICK2;
A1X:=(A1-REF(A1,1))/REF(A1,1)*100,NODRAW;
A2X:=(A2-REF(A2,1))/REF(A2,1)*100,NODRAW;
看多:IF(A1X>=0 AND BARSLAST(CROSS(A1X,0))>0,REF((C+O)/2,BARSLAST(CROSS(A1X,0))),DRAWNULL),COLORMAGENTA{,LINETHICK2};
逃顶:IF(A1X<0 AND BARSLAST(CROSS(0,A1X))>0,REF((C+O)/2,BARSLAST(CROSS(0,A1X))),DRAWNULL),COLORCYAN,{LINETHICK2};
买入持股:IF(A1X>=0,A1,DRAWNULL)COLORRED,LINETHICK3;
卖出空仓:IF(A1X<0 AND A2X<0,A1,DRAWNULL)COLORGREEN,LINETHICK3;
STICKLINE(CROSS(A1X,0),H,L,0,0 ),COLOR9933FF;
STICKLINE(CROSS(A1X,0),C,O,3,0 ),COLOR0000CC;
STICKLINE(CROSS(A1X,0),C,O,1,0 ),COLOR0033FF;
STICKLINE(CROSS(0,A1X),L,H,0,0 ),COLOR66CC33;

通达信小双阳选股指标（选股型）指标公式

核心逻辑

该指标寻找一种“小双阳”形态的股票。具体原理是：首先要求前期（3-7天内）出现过一根“将军阳”（即3天前的K线是放量的阳线，且收盘价高于4天前的开盘价，同时当前股价高于3天前股价，且低点未跌破）；然后要求前两天出现“接力阳”（第二天收盘价高于开盘价或前一天收盘价，且高于3天前的开盘价，但成交量萎缩）；同时要求近期5天的最低点高于12天前的最低点（底部抬升）；最后要求当前股价高于10天前股价但涨幅不超过12%（低位横盘蓄势）。

买卖信号

- **买入信号**：当“小双阳”条件全部满足时产生买入信号 - **卖出信号**：该指标没有明确的卖出条件，主要用于选股和买入时机判断

用法

1. 作为**选股指标**使用，筛选出符合“小双阳”形态的股票 2. “将军阳”代表前期有强势资金入场，“二阳”代表短期有接力上涨意愿 3. “底部抬升”表明股价处于上升趋势中，“趴着”表示当前处于相对低位蓄势状态 4. 建议结合其他技术指标或基本面分析进一步验证，不要单独使用

公式源码

将军阳:=REF(C,3)>REF(O,3) AND REF(C,3)>REF(O,4) AND REF(V,3)>REF(V,4) AND C>REF(C,3) AND LLV(L,3)<=REF(L,3);
底部抬升:=LLV(L,5)>LLV(L,12);
一阳:=REF(将军阳,3) OR REF(将军阳,4) OR REF(将军阳,5) OR REF(将军阳,6) OR REF(将军阳,7);
二阳:=(REF(C,2)>REF(O,2) OR REF(C,2)>REF(C,1)) AND REF(C,2)>REF(O,3) AND REF(C,3)<REF(O,3) AND REF(C,2)/REF(C,3)>1 AND C>O AND V<REF(V,2);
趴着:=C>REF(C,10) AND (C-REF(C,10))/REF(C,10)<0.12;
小双阳:一阳 AND 二阳 AND 底部抬升 AND 趴着;

通达信小双龙主图指标（布林带类）指标公式

核心逻辑

该指标是一个**布林带与KDJ指标的组合指标**。它包含两套布林带系统： 1. **第一套布林带**：使用55日EMA计算上下轨（绿色），用于判断股价相对于短期均价的位置 2. **第二套布林带**：使用31日MA作为中轨，配合2倍标准差计算上下轨（黄/洋红色），这是传统的布林带指标 同时叠加了KDJ指标的J线，用于判断超买超卖状态。

买卖信号

**买入信号**： - KDJ的J值从下方上穿0轴（笑脸图标） - 股价在布林带下轨附近获得支撑 **卖出信号**： - KDJ的J值从上方下穿100（哭脸图标） - 股价跌破布林带下轨

用法

1. **布林带用法**：当布林带震动波带变窄时，表示行情即将发生变盘；当股价上穿上轨时，回调概率大；当股价下穿下轨时，反弹概率大 2. **KDJ用法**：J值上穿0轴为超卖区域的买入信号，J值下穿100为超买区域的卖出信号 3. **综合判断**：可结合两套指标综合判断，例如在布林带下轨附近，同时KDJ出现买入信号时，买入可靠性更高

公式源码

{使用说明：1.股价上升穿越布林线上限时，回档机率大；2.股价下跌穿越布林线下限时，反弹机率大；3.布林线震动波带变窄时，表示变盘在即；}					
					上轨:EMA(H,55),COLORGREEN;
下轨:EMA(L,55),COLORGREEN;
NOTEXT_A111:=PLOYLINE(C>上轨,上轨);
NOTEXT_A222:IF(C>上轨,NOTEXT_A111,DRAWNULL),COLORRED;
NOTEXT_B111:=PLOYLINE(C>下轨,下轨);
NOTEXT_B222:IF(C>下轨,NOTEXT_B111,DRAWNULL),COLORRED;
DRAWICON(crOSS(100,"kdj.J"(9,3,3)),H*1.02,4);{哭脸}
DRAWICON(CROSS("kdJ.J"(9,3,3),0),L*0.997,3);{笑脸}
DRAWKLINE(HIGH,OPEN,LOW,CLOSE);
boll:=MA(CLOSE,31),COLORBROWN;
UB:BOLL+2*STD(CLOSE,31),COLORYELLOW;
LB:BOLL-2*STD(CLOSE,31),COLORMAGENTA;

通达信黄金波浪线主图指标（其他）指标公式

核心逻辑

该指标是一个综合型趋势判断工具，主要包含以下核心逻辑： 1. **多周期均线系统**：通过EMA(8,13,62)构建长期趋势线VAR1，用于判断市场整体趋势方向 2. **价格波动带**：VAR3（10日均价EMA）与VAR4（前日VAR3）对比，反映短期价格动量变化 3. **RSI超买判断**：VAR8计算7日RSI，VAR9检测RSI从高位下穿69的信号（表示超买区域回落） 4. **布林带思路**：VAR6计算17日均价+2倍标准差，作为价格上轨参考 5. **特殊买入条件**：VAR10是一个自定义的"价值区间"指标（80日均线-10日均线/3），用于捕捉低位机会

买卖信号

**买入信号：** - VAR3上穿VAR4（短期均线向上突破前一天位置），显示短期转强 - 满足条件：收盘价<VAR10 且 成交量/240>5日均量/240 且 收盘价>前一日收盘价*1.08 且 收盘价<13日均线*1.3（符合条件时显示"●进场"） **卖出信号：** - CROSS(LH,VAR12)：当17日RSI从低位上穿79时，显示"获利减仓"（这是超买信号） **图形显示：** - VAR3>VAR4时显示黄色柱状线（上涨趋势） - VAR3<VAR4时显示红色柱状线（下跌趋势）

用法

1. **趋势判断**：观察STICKLINE颜色，黄线持股，红线持币 2. **买入时机**：当出现"●进场"文字提示时，是相对安全的买入点 3. **卖出时机**：当出现"获利减仓"提示时，考虑减仓或卖出 4. **结合均线**：可配合13日均线（MA(CLOSE,13

公式源码

N:=17;
N1:=7;
N2:=69;
LH:=79;
M8:=EMA(CLOSE,8);
M13:=EMA(M8,13);
VAR1:=EMA(M13,62);
VAR2:=(CLOSE+HIGH+LOW)/3;
VAR3:=EMA(VAR2,10);
VAR4:=REF(VAR3,1);
STICKLINE(VAR3>VAR4,VAR3,VAR4,2,0),COLOR00FFFF;
STICKLINE(VAR3<VAR4,VAR3,VAR4,2,0),COLORFF0000;
VAR5:=(REF(HIGH,1)+REF(LOW,1))/2;
VAR6:=MA(CLOSE,N)+2*STD(CLOSE,N);
VAR7:=REF(CLOSE,1);
VAR8:=(SMA(MAX(CLOSE-VAR7,0),N1,1))/(SMA(Abs(CLOSE-VAR7),N1,1))*100;
VAR9:=crOSS(N2,VAR8);
VARA:=FILTER(VAR9,4);
VARB:=(2*CLOSE+HIGH+LOW)/4;
VARC:=LLV(LOW,34);
VARD:=HHV(HIGH,34);
VARE:=EMA((VARB-VAR1)/(VAR5-VAR1)*100,7);
VARF:=EMA(0.667*REF(VARE,1)+0.333*VARE,5);
VAR10:=MA(CLOSE,80)-MA(CLOSE,10)/3;
DRAWTEXT(IF(CLOSE<VAR10 AND vol/240>MA(VOL,5)/240 AND CLOSE>REF(CLOSE,1)*1.08 AND CLOSE<MA(CLOSE,13)*1.3,1,0),LOW,'●进场'),COLOR00FF00;
VAR11:=REF(CLOSE,1);
VAR12:=(SMA(MAX(CLOSE-VAR11,0),N,1))/(SMA(ABS(CLOSE-VAR11),N,1))*100;
DRAWICON(CROSS(LH,VAR12),HIGH*1.035,1);
DRAWTEXT(CROSS(LH,VAR12),HIGH*1.04,'获利减仓');
买入:CROSS(VAR3,VAR4),LINETHICK0;

通达信小双底指标（均线型）指标公式

核心逻辑

该指标是一个综合型技术指标，主要包含两部分： 1. **跌幅计算**：计算当前价格相对于60日内最高价的跌幅比例 2. **均线交叉系统**：通过VAR1（加权均价）经过三重EMA平滑处理后，计算其变化率SJ，再分别计算SK（快线）和SD（慢线）的均线组合，类似于MACD的原理 3. **操作线系统**：用(L+H+C)/3计算三日均价，再取5日均线作为"操作线"，通过30日最高和13日最低来判断支撑压力位

买卖信号

**买入条件（小双底信号）**： - 10日内出现过操作线上穿买卖线的黄金交叉（JC） - 当前股价低于买卖线 - 买卖线等于5日前的买卖线（横盘整理状态） **其他参考信号**： - SK上穿SD（多头信号） - 7日内振幅在7%-18%之间（横盘震荡特征）

用法

1. 主要关注"小双底"红色信号出现时，表示股价在低位横盘后有反弹机会 2. 配合SK与SD的多头排列（SK>SD）增强买入信心 3. 跌幅较大时（负值大）可能存在超跌反弹机会 4. 该指标适合捕捉横盘整理后的突破行情

公式源码

跌幅:(1-HHV(C,60)/C),COLORGREEN;
VAR1:=(2*CLOSE+HIGH+LOW+OPEN)/5;
VAR2:=EMA(EMA(EMA(VAR1,4),4),4);
SJ:=(VAR2-REF(VAR2,1))/REF(VAR2,1)*100;
SD:=MA(SJ,2);
SK:=MA(SJ,1);VAR4:=(LOW+HIGH+CLOSE)/3; 
操作:=MA(VAR4,5);
XZX:=HHV(操作,30); 
买卖:=LLV(操作,13); 
J:=买卖+0.0001;
JC:=crOSS(操作,J);
Z，:=(HHV(H,7)-LLV(L,7))/LLV(L,7)>0.07 AND (HHV(H,7)-LLV(L,7))/LLV(L,7)<0.18;
LSJC:=COUNT(SK>=SD,7)>0;
QD:=LLV(SK,12);
小双底:COUNT(JC,10)>0 AND L<买卖 AND 买卖=REF(买卖,5) ,COLORRED;

通达信小试牛刀指标（其他）指标公式

核心逻辑

该指标是一个综合型技术指标，包含三个主要部分： 1. **VAR1（核心动力指标）**：基于5日周期计算短期价格动量，是对传统KDJ指标的变形，通过双重SMA平滑处理，数值越低表示股价越接近短期底部。 2. **VARO7（建仓区判断）**：基于27日低点和34日高点计算价格相对位置，数值低于10表示股价处于相对低位区域。 3. **端庄窝（趋势动量指标）**：基于9日周期计算价格趋势强度，当该值超过21时说明趋势转强。

买卖信号

**买入信号：** - **小试牛刀**：VAR1上穿8（红色柱状） - **果断出击**：端庄窝上穿0.01（蓝色柱状） - **建仓区**：VARO7<10时显示 **卖出信号：** - **减仓空仓**：CD6下穿CD5（绿色图标） - **E信号**：RSI上穿83时表示超买（风险提示）

用法

1. **综合判断**：当"小试牛刀"和"果断出击"同时出现时，是较强的买入信号 2. **建仓区参考**：当出现"建仓区"信号时，可考虑分批建仓 3. **风险提示**：出现"减仓空仓"信号或E信号时，应考虑减仓或卖出 4. **趋势判断**：红持绿空柱状图显示端庄窝的变化方向，红色上涨趋势，绿色下跌趋势 5. **配合其他指标**：建议结合成交量、均线等指标综合判断

公式源码

N:=5; N1:=21;
VAR1:=4*SMA((CLOSE-LLV(LOW,N))/(HHV(HIGH,N)-LLV(LOW,N))*100,5,1)-
3*SMA(SMA((CLOSE-LLV(LOW,N))/(HHV(HIGH,N)-LLV(LOW,N))*100,5,1),3.2,1),COLORYELLOW,LINETHICK1;
VAR2:=8,COLORGREEN,LINETHICK0;
小试牛刀: IF(crOSS(VAR1,VAR2),8,0),STICK,COLORRED;
DRAWICON(小试牛刀>0,8,23);
发现庄迹: IF(VAR1<=8,15,0),STICK,COLORCYAN,LINETHICK2;
VARO5:=LLV(LOW,27);
VARO6:=HHV(HIGH,34);
VARO7:=EMA((CLOSE-VARO5)/(VARO6-VARO5)*4,4)*25;
建仓区: IF((VARO7<10),100,118) ,COLOR00CCFF,LINETHICK1;
CD1:=(HHV(H,9)-C)/(HHV(H,9)-LLV(L,9))-0.7;
CD2:=(C-LLV(L,9))/(HHV(H,9)-LLV(L,9));
CD3:=SMA(SMA(CD2,3,1),3,1);
CD4:=(CD3-SMA(CD1,9,1))-0.5;
CD5:=IF(CD4>0.00,CD4,0.00);
CD6:=REF(CD5,1);
VAR81:=MA(C,9),COLORRED;
空头1:=IF(CD6-CD5,CD6,CD5),LINETHICK3,COLORGREEN;
减仓空仓:CROSS(CD6,CD5),COLORGREEN;
DRAWICON(减仓空仓>0,113,2);
VAR1A:=(HHV(HIGH,9)-CLOSE)/(HHV(HIGH,9)-LLV(LOW,9))*100-70;
VAR2A:=SMA(VAR1A,9,1)+100;
VAR3A:=(CLOSE-LLV(LOW,9))/(HHV(HIGH,9)-LLV(LOW,9))*100;
VAR4A:=SMA(VAR3A,3,1);
VAR5A:=SMA(VAR4A,3,1)+100;
VAR6A:=VAR5A-VAR2A;
端庄窝:=IF(VAR6A>N1,VAR6A-N1,0),COLORLIRED;
果断出击:IF(CROSS(端庄窝,0.01),18,0),STICK,COLOR0000CC,LINETHICK2;
DRAWICON(果断出击>0,18,1);
XG:=CROSS(端庄窝,0.01);
LC:=REF(CLOSE,1); 
rsi:=SMA(MAX(CLOSE-LC,0),6,1)/SMA(Abs(CLOSE-LC),6,1)*100;
E:=CROSS(83,RSI);
STICKLINE(REF(端庄窝,1)<端庄窝,端庄窝,REF(端庄窝,1),3,0),COLORRED;
STICKLINE(REF(端庄窝,1)>端庄窝,端庄窝,REF(端庄窝,1),3,0),COLOR00FF00;
红持绿空:0,COLORGREEN;

通达信小试牛刀选股指标（其他）指标公式

核心逻辑

这是一个综合型技术指标，融合了趋势判断、超卖捕捉和资金流向分析。核心原理是： 1. **多周期位置计算**：通过计算价格在21日、37日、55日周期内的相对位置（RSV），判断股价的短期、中期、长期超卖程度 2. **均线偏离分析**：通过BIAS指标计算股价与均线（6日、12日、24日）的偏离程度，捕捉严重超跌的反弹机会 3. **资金流向监控**：利用EMA的变动率（VAR2）监控主力资金动向 4. **多周期共振**：同时使用月线、周线级别的MACD和KDJ指标，要求中长期趋势向上 整体思路是寻找"黄金坑"（严重超卖）+"主升浪"（资金流入+趋势向好）的共振买点。

买卖信号

**买入条件（介入信号）**： -

用法

公式源码

RSV1:=(CLOSE-LLV(LOW,21))/(HHV(HIGH,21)-LLV(LOW,21))*100;
RSV2:=(CLOSE-LLV(LOW,37))/(HHV(HIGH,37)-LLV(LOW,37))*100;
短线:=SMA(SMA(RSV1,3,1),3,1)+3*STD(CLOSE,21);
中线:=SMA(RSV2,5,1)+2*STD(CLOSE,37);
RSV3:=(CLOSE-LLV(LOW,55))/(HHV(HIGH,55)-LLV(LOW,55))*100;
长线:=SMA(RSV3,5,1);
看底:=STICKLINE(中线<15,中线,15,6,0);
黄金坑:=STICKLINE(短线<20 AND 中线<20 AND 长线<20,MAX(长线,MAX(短线,中线)),20,8,0);
VAR1:=EMA(EMA(CLOSE,13),13);
VAR2:=(VAR1-REF(VAR1,1))/REF(VAR1,1)*1000;
VAR3:=DYNAINFO(11);
VAR4:=(EMA(CLOSE,8)-EMA(CLOSE,55))*10;
VAR5:=EMA(VAR4,3);
VAR6:=(CLOSE-VAR3)/VAR3<(-0.03);
VAR7:=VAR2>REF(VAR2,1) AND VAR2<(-0.2);
VAR8:=crOSS(VAR4,VAR5) AND VAR4<(-0.3);
主升浪:=FILTER(VAR6 AND VAR7 AND VAR8,13);
bias11:=(CLOSE-MA(CLOSE,6))/MA(CLOSE,6)*100;
BIAS21:=(CLOSE-MA(CLOSE,12))/MA(CLOSE,12)*100;
BIAS31:=(CLOSE-MA(CLOSE,24))/MA(CLOSE,24)*100;
BIAS:=(BIAS11+2*BIAS21+3*BIAS31)/6;
乖离:=MA(BIAS,3);
极底:=CROSS(BIAS,乖离) AND 乖离<(-9);
DIF:=EMA(CLOSE,12)-EMA(CLOSE,26);
DEA:=EMA(DIF,9);
周DIF:=MA(macd.DIF#WEEK,5);
周DEA:=MA(MACD.DEA#WEEK,5);
月DIF:=MA(MACD.DIF#MONTH,20);
月DEA:=MA(MACD.DEA#MONTH,20);
RSV:=(CLOSE-LLV(LOW,18))/(HHV(HIGH,18)-LLV(LOW,18))*100;
K:=SMA(RSV,3,1);
D:=SMA(K,3,1);
月K:=MA(kdj.K#MONTH(9,3,3),20);
月D:=MA(kdJ.D#MONTH(9,3,3),20);
月J:=MA(KDJ.J#MONTH(9,3,3),20);
周K:=MA(KDJ.K#WEEK(9,3,3),5);
周D:=MA(KDJ.D#WEEK(9,3,3),5);
周J:=MA(KDJ.J#WEEK(9,3,3),5);
XG1:=月DIF>=REF(月DIF,1) AND 周DIF>=REF(周DIF,1);
XG2:=月K>=REF(月K,1) AND 周K>=REF(周K,1);
GZXG:=IF(XG1 AND XG2,20,0);
介入:BARSLAST(极底)<13 OR BARSLAST(主升浪)<13 AND GZXG=20 AND REF(GZXG,1)=0 OR (主升浪 AND GZXG) , COLORBLUE,LINETHICK2;

通达信小试牛刀及选股指标（趋势型）指标公式

核心逻辑

该指标是一个综合型趋势判断指标，主要包含以下几个计算逻辑： 1. **价格基准计算**：用"卖"（最低价、最高价、收盘价的均值）计算5日均线"奇"，再取10日最高值"准"作为参考价位。 2. **ADX波动率计算**：通过真实波幅（TTR）、上升幅度（DMP）和下降幅度（DMM）计算市场趋势强度，得出"神偷线"（代表多方强度）和"辅助线"（代表空方强度）。 3. **趋势信号**：计算两条线的偏离程度（XXX），数值越大表示趋势越明显。 4. **买入条件**：当价格低于10日最低均线时视为潜在买入机会，结合XXX数值和神偷线判断底部区域。

买卖信号

**卖出信号：** - 急卖：买<准持续5天，提示短期风险 - 短卖：买<准持续10天，提示中期调整 **买入信号：** - 底部关注：XXX>88且神偷线<5.8，表示超卖可能见底 - 小试牛刀：买<买卖持续5天 - 短买：买<买卖持续10天

用法

1. **观察动向趋势线**：数值越高代表趋势越强，可作为参考 2. **红色彩柱出现**（小试牛刀/短买）：表示短期可能见底，可考虑分批建仓 3. **绿色/粉色柱状线**（短卖/急卖）：提示价格可能进入调整期 4. **黄色柱状线**（底部关注）：强烈超卖信号，可能产生较大反弹 5. 可结合其他指标如MACD、均线等综合判断，提高准确率

公式源码

买:=MA(CLOSE,1);
卖:=(LOW+HIGH+CLOSE)/3;
奇:= MA(卖,5);
准:= HHV(奇,10);
急卖:IF(HHV((买<准),5),50,10),COLORFF6699;
STICKLINE(急卖=10,50,10,1,1),COLORFF6699;
短卖:IF(HHV((买<准),10),50,20),COLORGREEN;
STICKLINE(短卖=20,50,20,1,0),COLORGREEN;
TTR:=SUM(MAX(MAX((HIGH - LOW),Abs((HIGH - REF(CLOSE,1)))),ABS((LOW - REF(CLOSE,1)))),5);
HD:=(HIGH - REF(HIGH,1));
LD:=(REF(LOW,1) - LOW);
DMP:=(SUM(IF(((HD > 0) AND (HD > LD)),HD,0),5) );
DMM:=SUM(IF(((LD > 0) AND (LD > HD)),LD,0),5);
神偷线:=(((DMP ) * 100) / TTR);
辅助线:=((DMM * 100) / TTR);
XXX:=(MA(((ABS((辅助线 - 神偷线)) / (辅助线 + 神偷线)) * 100),3));
奇准:= MA(卖,5);
买卖:=LLV(奇准,10);
底部关注:IF(((XXX > 88) AND (神偷线 < 5.8)),95,50),LINETHICK1,COLORYELLOW;
STICKLINE(底部关注=95,50,95,1.5,0),COLORYELLOW,LINETHICK1;
小试牛刀:IF(LLV((买<买卖),5),75,50),COLORRED,LINETHICK1;
STICKLINE(小试牛刀=75,50,75,1.5,0),COLORRED,LINETHICK1;
短买:IF(LLV((买<买卖),10),85,50),COLORRED,LINETHICK1;
STICKLINE(短买=85,50,85,1.5,0),COLORRED,LINETHICK1;
ADXR:=((XXX + REF(XXX,3)) / 2);
VAR1:=MA(LOW,1);
VAR2:=MA(HIGH,2);
VAR3:=MA(CLOSE,2);
VAR7:=REF(VAR3,1);
动向趋势线:XXX,LINETHICK2,COLORFFAA66;
{
选股公式:
买:=MA(CLOSE,1);
卖:=(LOW+HIGH+CLOSE)/3;
奇:= MA(卖,5);
准:= HHV(奇,10);
TTR:=SUM(MAX(MAX((HIGH - LOW),ABS((HIGH - REF(CLOSE,1)))),ABS((LOW - REF(CLOSE,1)))),5);
HD:=(HIGH - REF(HIGH,1));
LD:=(REF(LOW,1) - LOW);
DMP:=(SUM(IF(((HD > 0) AND (HD > LD)),HD,0),5) );
DMM:=SUM(IF(((LD > 0) AND (LD > HD)),LD,0),5);
神偷线:=(((DMP ) * 100) / TTR);
辅助线:=((DMM * 100) / TTR);
XXX:=(MA(((ABS((辅助线 - 神偷线)) / (辅助线 + 神偷线)) * 100),3));
奇准:= MA(卖,5);
买卖:=LLV(奇准,10);
小试牛刀:LLV((买<买卖),5);
}

通达信小使者分时指标（均线型）指标公式

核心逻辑

这是一个基于EMA均线的趋势跟踪指标。公式包含三条EMA均线：5日（超短期）、25日（短期）和905日（长期），以及一个对25日均线进行60日平滑处理的MACP指标。银河线计算的是当日股价的波动范围（最高价与最低价之差）。核心原理是利用均线的交叉来判断趋势方向，当短期均线上穿长期均线时视为多头信号。

买卖信号

- **买入信号**：MA25上穿MACP时（短期25日均线从下向上突破60日平滑均线），系统会显示买入图标（23号图标）

用法

1. 观察MA25与MACP的交叉情况，当MA25从下方突破MACP时，可能产生买入机会 2. 银河线（波动幅度）可辅助判断当日股价活跃程度 3. 建议结合其他技术指标或趋势线进行综合判断，避免单一指标决策 4. 该指标偏中长线趋势判断，适合波段操作

公式源码

MA25:EMA(CLOSE,25);
FJ:EMA(CLOSE,905);
EXP1:EMA(CLOSE,5);
X_3:=MAX(DYNAINFO(3),DYNAINFO(5));
X_4:=MIN(DYNAINFO(3),DYNAINFO(6));
银河线:=(X_3-X_4);
MACP:EMA(MA25,60),COLORBLUE,LINETHICK2;
DRAWICON(crOSS(MA25,MACP),MACP,23);

通达信小神仙秘密线分时指标（其他）指标公式

核心逻辑

这是一个综合型技术指标，融合了均线系统、成交量分析、相对强弱判断和涨停板捕捉等多维度分析逻辑。主要包含： 1. **均线系统**：使用24日、25日EMA均线作为支撑压力位，通过均线金叉死叉判断趋势 2. **相对强弱**：将个股与大盘指数对比（HJ_12/HJ_13/HJ_14），判断个股相对强弱 3. **成交量分析**：统计放量上涨和放量下跌的累积量（HJ_30/HJ_31） 4. **超跌反弹**：通过变形RSI指标（HJ_15/HJ_16）捕捉超跌反弹信号 5. **涨停板识别**：多重条件验证涨停板的有效性 6. **趋势确认**：结合价格形态、量价配合判断趋势延续性

买卖信号

- **买入信号**： - HJ_40上穿HJ_41（DRAWICON显示红色图标） - HJ_16（变形RSI探底回升）成立 - HJ_2、HJ_4、HJ_6等均线交叉信号 - HJ_17、HJ_52等涨停板启动信号 - HJ_18、HJ_55等趋势确认信号 - **卖出信号**： - HJ_41上穿HJ_40（DRAWICON显示绿色图标） - 相对指数走弱（HJ_46<HJ_47） - 高位放量滞涨

用法

1. **单独使用**：DRAWICON的金叉死叉信号作为基础买卖点 2. **综合判断**：结合NOTEXT1（放量上涨）和NOTEXT2（放量下跌）的累积量能

公式源码

HJ_1:=MA(LOW,24)*1.09;
HJ_2:=crOSS(HJ_1,OPEN);
HJ_3:=MA((LOW+HIGH+CLOSE+OPEN)/4,25)*1.23;
HJ_4:=CROSS(HJ_3,OPEN);
HJ_5:=EMA(LOW,25);
HJ_6:=CROSS(CLOSE,HJ_5);
HJ_7:=REF(COUNT(REF(EMA(CLOSE,5)/REF(EMA(CLOSE,5),1)<1,1) AND EMA(CLOSE,5)/REF(EMA(CLOSE,5),1)>1,11)>=1,3) AND REF(EMA(CLOSE,5)/REF(EMA(CLOSE,5),1)>0.987,1) AND COUNT(OPEN<CLOSE,7)/7>5/10 AND REF(COUNT(CLOSE/REF(CLOSE,1)>1.08 OR CLOSE/REF(CLOSE,2)>1.08 AND CLOSE/OPEN>1.038,25)>=1,3) AND COUNT(CLOSE>OPEN,2)=2 AND CLOSE>REF(CLOSE,1) AND (LOW<MA(CLOSE,5) OR REF(LOW<MA(CLOSE,5) AND CLOSE/REF(CLOSE,1)>1.095 AND HIGH=CLOSE,1) OR (COUNT(LOW>MA(CLOSE,5),3)=3 AND OPEN/MA(CLOSE,5)<1.015)) AND COUNT(REF(CLOSE<REF(CLOSE,1),1) AND CLOSE>OPEN,9)>=2 AND REF(COUNT(CLOSE>OPEN AND HIGH>MA(CLOSE,5) AND CLOSE/REF(CLOSE,1)<1.095,5)>=1,1) AND CLOSE>MA(CLOSE,5);
HJ_8:=REF(COUNT(HJ_5,2)>0,3) AND (OPEN<REF(OPEN,1) OR LOW<REF(LOW,1) OR vol>REF(VOL,1));
HJ_9:=REF(COUNT(CLOSE/REF(CLOSE,1)>1.095 AND HIGH=CLOSE,5)>=1 AND OPEN>MA(CLOSE,5),3) AND REF(COUNT(HIGH/LOW>1.095 AND CLOSE<HIGH,2)>=1,2) AND REF(CLOSE/REF(CLOSE,1)<0.907 AND LOW/CLOSE>0.996 AND COUNT(HIGH>OPEN,2)>=1 AND COUNT(VOL>REF(VOL,1),3)>=1,1) AND REF(CLOSE,1)/LOW>1.04 AND CLOSE/LOW>1.02;
HJ_10:=HJ_9 AND OPEN/LOW<1.033 AND VOL<HHV(VOL,3) OR (REF(COUNT(HJ_9,2)>=1,3) AND REF(CLOSE/REF(CLOSE,1)<0.911,1) AND OPEN/REF(CLOSE,1)>0.998 AND OPEN/REF(CLOSE,1)<1.033) OR (REF(HJ_9,4) AND REF(COUNT(CLOSE/REF(CLOSE,1)<0.907,2)>=1,1) AND (REF(CLOSE,1)/LOW>1.086 AND CLOSE/LOW>1.02 OR (OPEN/REF(CLOSE,1)>0.998 AND OPEN/REF(CLOSE,1)<1.033)));
HJ_11:=HJ_10 AND OPEN/LOW<1.033 AND OPEN/CLOSE<1.033 OR (REF(COUNT(HJ_10,2)>=1,3) AND REF(CLOSE/REF(CLOSE,1)<0.911 OR (OPEN<REF(CLOSE,1) AND CLOSE/REF(CLOSE,1)<0.95),1) AND OPEN/REF(CLOSE,1)>0.998 AND OPEN/REF(CLOSE,1)<1.033 AND OPEN/CLOSE<1.033) OR (REF(HJ_9,4) AND REF(COUNT(CLOSE/REF(CLOSE,1)<0.907,2)>=1,1) AND OPEN/CLOSE<1.033 AND (REF(CLOSE,1)/LOW>1.086 AND CLOSE/LOW>1.02 OR (OPEN/REF(CLOSE,1)>0.998 AND OPEN/REF(CLOSE,1)<1.033)));
HJ_12:=1000*CLOSE/INDEXC;
HJ_13:=1000*OPEN/INDEXO;
HJ_14:=1000*LOW/INDEXL;
HJ_15:=100*EMA(EMA(CLOSE-REF(CLOSE,1),6),6)/EMA(EMA(Abs(CLOSE-REF(CLOSE,1)),6),6);
HJ_16:=LLV(HJ_15,2)=LLV(HJ_15,7) AND COUNT(HJ_15<0,2) AND CROSS(HJ_15,MA(HJ_15,2));
HJ_17:=CLOSE/REF(CLOSE,1)>=1.08 OR CLOSE/OPEN>1.06 AND (HJ_16 AND NOT(HJ_2) AND NOT(REF(HJ_2,4)) AND (NOT(REF(HJ_6 AND HJ_16,3)) AND NOT(REF(HJ_16 AND REF(CLOSE>OPEN,1),3))) OR (REF(HJ_16,4) AND CLOSE/REF(CLOSE,1)>1.095 AND HIGH=CLOSE AND REF(COUNT(HJ_12<HJ_13,5)>=1,1) AND REF(HJ_12>HJ_13,3)) OR (REF(HJ_11 OR REF(HJ_11,4),1) AND CLOSE/REF(CLOSE,1)>1.095 AND HIGH=CLOSE)) AND LOW>REF(LOW,1) AND LOW/MA(CLOSE,5)<1.025;
HJ1:=REF(COUNT(HJ_17,3)>=1,2) AND REF(CLOSE>=OPEN AND REF(CLOSE/REF(CLOSE,1)>=1.08 OR CLOSE/OPEN>1.067 AND CLOSE/REF(CLOSE,1)>=1.078,1) AND HIGH/CLOSE>1.025 AND HIGH/CLOSE>OPEN/LOW,1) AND CLOSE>=REF(OPEN,1) AND OPEN/REF(CLOSE,1)<1.03 AND COUNT(LOW/MA(CLOSE,5)<1.027,2)>=1;
HJ2:=(COUNT(HJ_12>HJ_13,3)=3 OR (COUNT(HJ_12>HJ_13,3)>=2 AND REF(HJ_11,3) AND REF(CLOSE/REF(CLOSE,1)>1.095 AND HIGH=CLOSE,2)));
HJ_18:=HJ1 AND (HJ_13/HJ_14>REF(HJ_13/HJ_14,2) OR REF(HJ_16,5) AND REF(REF(REF(COUNT(HJ_12>HJ_13,4)>=1,1) AND HJ_12<HJ_13,1) OR HJ_12>HJ_13,7) AND REF(HIGH/1.03<REF(HHV(HIGH,3),1),2) OR (REF(COUNT(HJ_12>HJ_13,2)=2,7) AND REF(COUNT(HJ_12<HJ_13,3)>=1,6) AND REF(HJ_12<HJ_13,4) AND REF(HIGH,2)>REF(HIGH,3)) OR REF(COUNT(HJ_12>HJ_13,2)=2 AND (REF(HJ_12<HJ_13,7) OR REF(HJ_12>HJ_13,2)),3) OR REF(COUNT(HJ_12>HJ_13,3)=3 AND REF(HJ_12>HJ_13,6),4) OR (REF(COUNT(HJ_12>HJ_13,2)=2,1) AND HJ_7 AND REF(HJ_12>HJ_13,6) AND REF(COUNT(HJ_12<HJ_13,3)>=1,7) AND REF(COUNT(HJ_12<HJ_13,3)>=2,3))) AND HJ_12/HJ_13>REF(HJ_12/HJ_13,1) AND CLOSE/OPEN>REF(CLOSE/OPEN,1) AND HJ2;
HJ_19:=CLOSE/REF(CLOSE,1)>=1.095 AND HIGH=CLOSE AND REF(CLOSE/OPEN<1.05,1) AND (COUNT(HJ_7,3)>=1 OR REF(HJ_4,1)) AND COUNT(LOW<REF(LOW,1),2)>=1 AND LOW<MA(CLOSE,5) AND NOT(REF(COUNT(CLOSE/REF(CLOSE,1)<0.923,3)>=1,1));
HJ_20:=REF(HJ_19,2) AND REF(CLOSE<=OPEN AND (HIGH/OPEN>1.043 AND REF(CLOSE>OPEN,4) OR (HIGH/CLOSE>1.089 AND OPEN/CLOSE>1.039 AND HIGH>OPEN AND REF(CLOSE/REF(CLOSE,1)>1.095 AND HIGH=CLOSE,1))),1) AND OPEN/LOW<1.029 AND OPEN/REF(LOW,3)>0.977 AND OPEN/REF(OPEN,2)<1.077 AND CLOSE/REF(CLOSE,1)>0.989 AND OPEN/REF(CLOSE,1)<1 AND COUNT(LOW<MA(CLOSE,5),2)>=1 AND REF(HJ_12<HJ_13,1) AND COUNT(HJ_12>HJ_13,3)>=2;
HJ_21:=MA(LOW,24)*1.09;
HJ_22:=CROSS(HJ_21,OPEN);
HJ_23:=MA((LOW+HIGH+CLOSE+OPEN)/4,25)*1.23;
HJ_24:=CROSS(HJ_23,OPEN);
HJ_25:=EMA(LOW,25);
HJ_26:=CROSS(CLOSE,HJ_25);
HJ_27:=REF(COUNT(REF(EMA(CLOSE,5)/REF(EMA(CLOSE,5),1)<1,1) AND EMA(CLOSE,5)/REF(EMA(CLOSE,5),1)>1,11)>=1,3) AND REF(EMA(CLOSE,5)/REF(EMA(CLOSE,5),1)>0.987,1) AND COUNT(OPEN<CLOSE,7)/7>5/10 AND REF(COUNT(CLOSE/REF(CLOSE,1)>1.08 OR CLOSE/REF(CLOSE,2)>1.08 AND CLOSE/OPEN>1.038,25)>=1,3) AND COUNT(CLOSE>OPEN,2)=2 AND CLOSE>REF(CLOSE,1) AND (LOW<MA(CLOSE,5) OR REF(LOW<MA(CLOSE,5) AND CLOSE/REF(CLOSE,1)>1.095 AND HIGH=CLOSE,1) OR (COUNT(LOW>MA(CLOSE,5),3)=3 AND OPEN/MA(CLOSE,5)<1.015)) AND COUNT(REF(CLOSE<REF(CLOSE,1),1) AND CLOSE>OPEN,9)>=2 AND REF(COUNT(CLOSE>OPEN AND HIGH>MA(CLOSE,5) AND CLOSE/REF(CLOSE,1)<1.095,5)>=1,1) AND CLOSE>MA(CLOSE,5);
HJ_28:=REF(COUNT(CLOSE/REF(CLOSE,1)>1.095 AND HIGH=CLOSE,5)>=1 AND OPEN>MA(CLOSE,5),3) AND REF(COUNT(HIGH/LOW>1.095 AND CLOSE<HIGH,2)>=1,2) AND REF(CLOSE/REF(CLOSE,1)<0.907 AND LOW/CLOSE>0.996 AND COUNT(HIGH>OPEN,2)>=1 AND COUNT(VOL>REF(VOL,1),3)>=1,1) AND REF(CLOSE,1)/LOW>1.04 AND CLOSE/LOW>1.02;
HJ_29:=HJ_28 AND OPEN/LOW<1.033 AND VOL<HHV(VOL,3) OR (REF(COUNT(HJ_28,2)>=1,3) AND REF(CLOSE/REF(CLOSE,1)<0.911,1) AND OPEN/REF(CLOSE,1)>0.998 AND OPEN/REF(CLOSE,1)<1.033) OR (REF(HJ_28,4) AND REF(COUNT(CLOSE/REF(CLOSE,1)<0.907,2)>=1,1) AND (REF(CLOSE,1)/LOW>1.086 AND CLOSE/LOW>1.02 OR (OPEN/REF(CLOSE,1)>0.998 AND OPEN/REF(CLOSE,1)<1.033)));
HJ_30:=SUM(IF(CLOSE>REF(CLOSE,1) AND VOL>4000,VOL/1000,0),0);
HJ_31:=SUM(IF(CLOSE<REF(CLOSE,1) AND VOL>4000,VOL/1000,0),0);
NOTEXT1:IF(HJ_30,HJ_30,0),COLORCC9932,LINETHICK4;
NOTEXT2:IF(HJ_31,HJ_31,0),COLORGREEN,LINETHICK2;
HJ_32:=(2*CLOSE+HIGH+LOW)/4;
HJ_33:=LLV(LOW,94);
HJ_34:=HHV(HIGH,89);
HJ_35:=EMA((CLOSE-HJ_33)/(HJ_34-HJ_33)*100,8);
HJ_36:=EMA(0.667*REF(HJ_35,1)+0.333*HJ_35,10);
HJ_37:=30;
HJ_38:=15;
HJ_39:=(CLOSE-LLV(LOW,40))/(HHV(HIGH,40)-LLV(LOW,40))*100;
HJ_40:=SMA(HJ_39,HJ_37,1);
HJ_41:=SMA(HJ_40,HJ_38,1);
HJ_42:=HJ_40;
HJ_43:=IF(HJ_42>REF(HJ_42,1),HJ_42,DRAWNULL);
HJ_44:=IF(HJ_42<REF(HJ_42,1),HJ_42,DRAWNULL);
DRAWICON(CROSS(HJ_40,HJ_41),HJ_40,1);
DRAWICON(CROSS(HJ_41,HJ_40),HJ_40,2);
HJ_45:=HJ_29 AND OPEN/LOW<1.033 AND OPEN/CLOSE<1.033 OR (REF(COUNT(HJ_29,2)>=1,3) AND REF(CLOSE/REF(CLOSE,1)<0.911 OR (OPEN<REF(CLOSE,1) AND CLOSE/REF(CLOSE,1)<0.95),1) AND OPEN/REF(CLOSE,1)>0.998 AND OPEN/REF(CLOSE,1)<1.033 AND OPEN/CLOSE<1.033) OR (REF(HJ_28,4) AND REF(COUNT(CLOSE/REF(CLOSE,1)<0.907,2)>=1,1) AND OPEN/CLOSE<1.033 AND (REF(CLOSE,1)/LOW>1.086 AND CLOSE/LOW>1.02 OR (OPEN/REF(CLOSE,1)>0.998 AND OPEN/REF(CLOSE,1)<1.033)));
HJ_46:=1000*CLOSE/INDEXC;
HJ_47:=1000*OPEN/INDEXO;
HJ_48:=1000*LOW/INDEXL;
HJ_49:=100*EMA(EMA(CLOSE-REF(CLOSE,1),6),6)/EMA(EMA(ABS(CLOSE-REF(CLOSE,1)),6),6);
HJ_50:=LLV(HJ_49,2)=LLV(HJ_49,7) AND COUNT(HJ_49<0,2) AND CROSS(HJ_49,MA(HJ_49,2));
HJ_51:=MA(CLOSE,5)<MA(CLOSE,10) AND LOW<MA(CLOSE,5) AND HIGH/OPEN>1.07 AND OPEN=LOW AND CLOSE>OPEN AND OPEN/REF(CLOSE,1)<0.95 AND HIGH/CLOSE>1.043 AND (VOL>REF(HHV(VOL,800),1) OR REF(CLOSE>LOW,1));
HJ_52:=CLOSE/REF(CLOSE,1)>=1.08 OR CLOSE/OPEN>1.06 AND (HJ_50 AND NOT(HJ_22) AND (NOT(REF(HJ_26 AND HJ_50,3)) AND NOT(REF(HJ_50 AND REF(CLOSE>OPEN,1),3))) OR (REF(HJ_50,4) AND CLOSE/REF(CLOSE,1)>1.095 AND HIGH=CLOSE AND REF(COUNT(HJ_46<HJ_47,5)>=1,1) AND REF(HJ_46>HJ_47,3)) OR (REF(HJ_45 OR REF(HJ_45,4),1) AND CLOSE/REF(CLOSE,1)>1.095 AND HIGH=CLOSE)) AND LOW>REF(LOW,1) AND LOW/MA(CLOSE,5)<1.025;
HJ_53:=REF(COUNT(HJ_52,4)>=1 AND CLOSE>OPEN AND REF(COUNT(CLOSE/REF(CLOSE,1)>1.095 AND HIGH=CLOSE,3)=3,1),3) AND REF(OPEN<REF(CLOSE,1) AND OPEN/CLOSE>1.01 AND HIGH/CLOSE>1.025 AND HIGH/CLOSE>OPEN/LOW,2) AND REF(CLOSE<OPEN AND HIGH/OPEN>CLOSE/LOW AND HIGH/OPEN>OPEN/CLOSE OR (CLOSE>OPEN AND HIGH/CLOSE>CLOSE/OPEN),1) AND (REF(CLOSE,1)<REF(OPEN,2) AND REF(CLOSE/OPEN<1,2) OR (REF(CLOSE,1)<REF(CLOSE,2) AND REF(CLOSE/OPEN>1,2))) AND (CLOSE/REF(CLOSE,1)>1.041 OR CLOSE/OPEN>1.039) AND REF(CLOSE/OPEN<1.051 OR CLOSE/REF(CLOSE,1)<1.051,1) AND (REF(LOW,1)<REF(LOW,2) OR REF(LOW,2)<REF(LOW,3) AND COUNT(CLOSE/REF(CLOSE,1)<0.9672 OR CLOSE/OPEN<0.9672,8)>=1 AND CLOSE>ACD AND (COUNT(CLOSE>ACD,2)>=1 OR REF(CLOSE/OPEN<1.051,1)) AND REF(COUNT(CLOSE/OPEN>1.0595,7)>=1 OR COUNT(CLOSE/REF(CLOSE,1)>1.0595,7)>=1,3) AND REF(CLOSE/OPEN<1.0097 OR CLOSE/REF(CLOSE,1)<1.0097,1) AND CLOSE>REF(CLOSE,1));
HJ_54:=REF(COUNT(HJ_52,3)>=1 AND CLOSE>OPEN AND REF(COUNT(CLOSE/REF(CLOSE,1)>1.095 AND HIGH=CLOSE,2)=2,1),5) AND REF(OPEN<REF(CLOSE,1) AND OPEN/CLOSE>1.01 AND HIGH/CLOSE>1 AND HIGH/CLOSE>OPEN/LOW,4) AND REF(HIGH/CLOSE>CLOSE/OPEN AND REF(CLOSE<REF(CLOSE,1),1),1) AND (CLOSE/REF(CLOSE,1)>1.041 OR CLOSE/OPEN>1.039) AND REF(CLOSE/OPEN<1.058 OR CLOSE/REF(CLOSE,1)<1.058,1) AND (REF(LOW,1)<REF(LOW,2) OR REF(LOW,2)<REF(LOW,3) AND COUNT(CLOSE/REF(CLOSE,1)<0.967 OR CLOSE/OPEN<0.967,8)>=1 AND CLOSE>ACD AND (COUNT(CLOSE>ACD,2)>=1 OR REF(CLOSE/OPEN<1.05,1)) AND REF(COUNT(CLOSE/OPEN>1.0595,7)>=1 OR COUNT(CLOSE/REF(CLOSE,1)>1.0595,7)>=1,3) AND (REF(CLOSE/OPEN<1,2) AND CLOSE>REF(CLOSE,2) OR (REF(CLOSE/OPEN>1,2) AND CLOSE>REF(OPEN,2))));
NOTEXT3:IF(HJ_35,HJ_35,0),COLORWHITE;
NOTEXT4:IF(HJ_43,HJ_43,0),COLORRED,LINETHICK2;
NOTEXT5:IF(HJ_44,HJ_44,0),COLORGREEN,LINETHICK2;
0,COLORGRAY,LINETHICK3;
HJ3:=REF(COUNT(HJ_52,3)>=1,2) AND REF(C>=O OR C/REF(C,1)<0.95,1) AND REF(C>=O AND REF(C/REF(C,1)>=1.08 OR C/O>1.067 AND C/REF(C,1)>=1.0785,1) OR (REF(COUNT(C/REF(C,1)>1.095 AND H=C,2)=2,2) AND O<REF(C,1) AND O/C>1.01) AND H/C>1.025 AND (H/C>O/L OR (C>O AND REF(C/REF(C,1)>1.095 AND H=C AND HJ_50,1))),1);
HJ4:=(REF(HJ_51 AND HJ_47/REF(HJ_47,1)>0.9,1) AND HJ_47>REF(HJ_47,1) AND O/L<1.045) AND REF(C/O<1.06,1) AND C/O>REF(C/O,1);
HJ5:=C>=REF(O,1) AND O/REF(C,1)<1.03 AND COUNT(L/MA(C,5)<1.027,2)>=1;
HJ6:=REF(REF(REF(COUNT(HJ_46>HJ_47,4)>=1,1) AND HJ_46<HJ_47,1) OR HJ_46>HJ_47,7);
HJ7:=HJ_47/HJ_48>REF(HJ_47/HJ_48,2) OR REF(HJ_50,5) AND HJ6 AND REF(H/1.03<REF(HHV(H,3),1),2);
HJ8:=(REF(COUNT(HJ_46>HJ_47,2)=2,7) AND REF(COUNT(HJ_46<HJ_47,3)>=1,6) AND REF(HJ_46<HJ_47,4) AND REF(H,2)>REF(H,3));
HJ_55:=HJ3 AND HJ5 AND (L>REF(L,1) OR O/REF(C,2)<0.97 AND (HJ7) OR HJ8 OR REF(COUNT(HJ_46>HJ_47,2)=2 AND (REF(HJ_46<HJ_47,7) OR REF(HJ_46>HJ_47,2)),3) OR REF(COUNT(HJ_46>HJ_47,3)=3 AND REF(HJ_46>HJ_47,6),4) OR (REF(COUNT(HJ_46>HJ_47,2)=2,1) AND HJ_27 AND REF(HJ_46>HJ_47,6) AND REF(COUNT(HJ_46<HJ_47,3)>=1,7) AND REF(COUNT(HJ_46<HJ_47,3)>=2,3))) AND HJ_46/HJ_47>REF(HJ_46/HJ_47,1) AND (COUNT(HJ_46>HJ_47,3)=3 OR (COUNT(HJ_46>HJ_47,3)>=2 AND (REF(HJ_45,3) AND REF(C/REF(C,1)>1.095 AND H=C,2)) OR (REF(COUNT(C/REF(C,1)>1.095 AND H=C,2)=2,3) AND REF(C>O,2)))) OR HJ4;
HJ_56:=CLOSE/REF(CLOSE,1)>=1.095 AND HIGH=CLOSE AND REF(CLOSE/OPEN<1.05,1) AND (COUNT(HJ_27,3)>=1 OR REF(HJ_24,1)) AND COUNT(LOW<REF(LOW,1),2)>=1 AND LOW<MA(CLOSE,5) AND NOT(REF(COUNT(CLOSE/REF(CLOSE,1)<0.923,3)>=1,1));
HJ_57:=REF(HJ_56,2) AND REF(CLOSE<=OPEN,1) AND (REF(HIGH/OPEN>1.043 AND REF(CLOSE>OPEN,4) OR (HIGH/CLOSE>1.089 AND OPEN/CLOSE>1.039 AND HIGH>OPEN AND REF(CLOSE/REF(CLOSE,1)>1.095 AND HIGH=CLOSE,1)),1) AND OPEN/LOW<1.029 AND OPEN/REF(OPEN,2)<1.077 OR (REF(HIGH/OPEN>1.025 AND REF(CLOSE>OPEN,4) OR (HIGH/CLOSE>1.089 AND OPEN/CLOSE>1.039 AND HIGH>OPEN AND REF(CLOSE/REF(CLOSE,1)>1.095 AND HIGH=CLOSE,1)),1) AND OPEN/LOW<1.053 AND REF(CLOSE<OPEN AND CLOSE/LOW<1.02,3))) AND OPEN/REF(LOW,3)>0.977 AND CLOSE/REF(CLOSE,1)>0.989 AND OPEN/REF(CLOSE,1)<1 AND COUNT(LOW<MA(CLOSE,5),2)>=1 AND REF(HJ_46<HJ_47,1) AND COUNT(HJ_46>HJ_47,3)>=2;
HJ_58:=REF(CLOSE,1)>REF(CLOSE,2) AND CLOSE/REF(CLOSE,1)<1.05 AND REF(CLOSE,1)/REF(OPEN,1)>1.05 AND OPEN<(REF(CLOSE,1)+REF(OPEN,1)+REF(HIGH,1))/3 AND CLOSE>OPEN AND CLOSE>REF(CLOSE,1);
HJ_59:=REF(COUNT(HJ_58,2)>0,1) AND (OPEN<REF(OPEN,1) OR LOW<REF(LOW,1) OR VOL>REF(VOL,1)) AND CLOSE/REF(CLOSE,1)>1.05 AND OPEN<MA(CLOSE,5) AND (REF(CLOSE>OPEN,1) OR CLOSE/REF(CLOSE,1)>1.07) AND OPEN<MA(CLOSE,10) AND CLOSE>MA(CLOSE,5) AND CLOSE>MA(CLOSE,10) AND MA(CLOSE,5)/MA(CLOSE,10)<0.98 OR (REF(CLOSE,1)>REF(OPEN,1) AND REF(OPEN=LOW AND CLOSE/OPEN>1.005,1) AND REF(HIGH/CLOSE>1.043 AND (OPEN/REF(CLOSE,1)<1.013 OR OPEN/REF(OPEN,1)<1.013),1) AND REF(REF(CLOSE<OPEN,1),3) AND REF(CLOSE,1)/REF(CLOSE,2)>0.937 AND OPEN<REF(OPEN,1) AND CLOSE/REF(CLOSE,1)>1.005 AND OPEN/LOW<1.041 AND OPEN/REF(OPEN,1)>0.98);
HJ_60:=HJ_53 OR HJ_54 OR HJ_55 OR HJ_57 OR HJ_59;