核心逻辑
这是一个基于威廉指标变形的综合选股指标体系。通过计算股价在最近N日内（5日、10日、20日、30日）所处的相对位置百分比（T1-T4），来判断当前价格处于近期的什么水平。数值越高表示股价越接近近期最高价，越低表示越接近近期最低价。 指标设计了8种不同形态的买入信号，分别对应不同的股价运行阶段和形态特征，包括：白金（强势启动）、黄金（趋势回调）、天瀑（上升中继）、日月（突破追涨）、青干（精准起涨）、莫问（波段启动）、竞星（趋势启动）、舍神（黄金坑）。同时底部设置了买入信号（当T1和T4都低于20时）。
买卖信号
**买入信号：** - **白金**：30日内强势股首次回调后重新启动 - **黄金**：短期回调后再次走强 - **天瀑**：上升趋势中的金三角形态 - **日月**：高位横盘后突破 - **青干**：精确捕捉起涨第一日 - **莫问**：波段启动前兆 - **竞星**：中线趋势启动点 - **舍神**：黄金坑震仓后的启动点 - **买入**：T1和T4同时低于20（超卖区域） **无明确卖出信号**，该指标主要用于识别各类买入时机。
用法
1. 观察T1-T4的走势，当T1上穿T4时表示短期强于长期，可能形成上升趋势 2. 当出现"白金"、"黄金"、"天瀑"等信号时，结合成交量和股价位置判断是否买入 3. "青干"信号适合精准把握起涨点，"舍神"信号适合捕捉黄金坑后的反弹 4. 底部"买入"信号（T1<20且T4<20）表示短期超卖，可能存在反弹机会 5. STICKLINE绘制了不同信号的区域，可直观看到当前处于哪个买入阶段
公式源码
T1:100*(C-LLV(L,5))/(HHV(C,5)-LLV(L,5)),COLOR0080FF;
T2:100*(C-LLV(L,10))/(HHV(C,10)-LLV(L,10)),COLOR008000;
T3:100*(C-LLV(L,20))/(HHV(C,20)-LLV(L,20)),COLORFF8000;
T4:100*(C-LLV(L,30))/(HHV(C,30)-LLV(L,30)),COLOR00FFFF;
{白金} {20T 10% 100%}
AA1:=BARSLAST(crOSS(30,T1))<2 AND BARSLAST(CROSS(T1,50))<2;
BB1:=BARSLAST(CROSS(T4,T1))<2 AND T1>T4;
EE1:=T1>60 AND T4>70;
白金:AA1 AND BB1 AND EE1,NODRAW,COLORWHITE;
{黄金} {20T 10% 94.05%}
AA2:=BARSLAST(CROSS(50,T1))<3 AND BARSLAST(CROSS(T1,50))<3;
BB2:=BARSLAST(CROSS(T4,T1))<2 AND T1>T4;
黄金:AA2 AND BB2,NODRAW,COLORYELLOW;
{天瀑} {启动金三角 （捉中线牛股起涨点）}
XG1:=BARSLAST(CROSS(T4,T1))<5 AND T1>T4;
天瀑:COUNT(XG1,3)=1 AND XG1,NODRAW,COLORRED;
{日月} {短线追涨 （高位横盘突破）}
A:=BARSLAST(CROSS(97,T1))<=1 AND BARSLAST(CROSS(T1,85))<=1;
B:=BARSLAST(CROSS(97,T2))<=1 AND BARSLAST(CROSS(T2,85))<=1;
A1:=A AND B;
AA:=BARSLAST(CROSS(97,T1))<=2 AND BARSLAST(CROSS(T1,85))<=1;
BA:=BARSLAST(CROSS(97,T2))<=2 AND BARSLAST(CROSS(T2,85))<=1;
A2:=AA AND BA ;
AAA:=BARSLAST(CROSS(97,T1))<=3 AND BARSLAST(CROSS(T1,85))<=1;
BAA:=BARSLAST(CROSS(97,T2))<=3 AND BARSLAST(CROSS(T2,85))<=1;
A3:=AAA AND BAA ;
B1:=REF(A1,1);
B2:=REF(A2,1);
B3:=REF(A3,1);
D1:=T1=100 AND T2=100 AND A1 ;
D2:=T1=100 AND T2=100 AND A2 ;
D3:=T1=100 AND T2=100 AND A3 ;
日月:D1 OR D2 OR D3,NODRAW,COLORCYAN;
{青干}{蓝三角启动 （精确定位起涨第一日）}
AA3:=BARSLAST(CROSS(95,T1))<=2;
BB3:=BARSLAST(CROSS(95,T2))<=2;
EE3:= T4<T1 AND T1<T2 AND T1<T3;
FF3:=T2>50 AND T3>50;
GG3:=T1=100 AND T2=100;
TX:=COUNT(GG3,2)=1;
青干:AA3 AND BB3 AND EE3 AND FF3 AND TX,NODRAW,COLORGREEN;
{莫问} {银边启动 （波段启动前兆）}
AA4:=T3=100;
BB4:=T4<90;
莫问:COUNT(A,2) = 2 AND B ,NODRAW,COLORBLUE;
{竞星}{启动金三角 （捉中线牛股起涨点）}
AA5:=T1=T2 AND T2=T3 AND T1=100 AND T4>96;
BB5:=COUNT(AA5,2)=1;
DD5:=T1<T2 AND T1<T3 AND T1<T4 AND T2<T3 AND T4<95;
YH:=INDEXC/REF(INDEXC,1)*REF(C,1);
YH1:=REF(C,1)+C-INDEXC/REF(INDEXC,1)*REF(C,1);
X1:=EMA(YH1,7);
X2:=EMA(YH1,14);
X3:=EMA(X1,14);
EE5:=X1>X2 AND X2>X3;
竞星:BB5 AND DD5 AND EE5,NODRAW,COLORMAGENTA;
{舍神} {阶段震仓启动点（黄金坑）}
AA6:=BARSLAST(CROSS(T4,T1))>3 AND BARSLAST(CROSS(T1,T4))<3;
BB6:=BARSLAST(CROSS(T4,T2));
DD6:=T3<T4 AND T2<T4;
EE6:=BARSLAST(CROSS(T4,T3))>3 AND BARSLAST(CROSS(T1,T4))<3;
FF6:=T2<T3 AND T2<T4 AND T2<T1 AND T1=100;
舍神:AA6 AND BB6 AND DD6 AND EE6 AND FF6,NODRAW,COLOR0080FF;
{画剑}
STICKLINE(白金=1,90,100,1,0),COLORWHITE;
STICKLINE(黄金=1,80,90,1,0),COLORYELLOW;
STICKLINE(天瀑=1,70,80,1,0),COLORRED;
STICKLINE(日月=1,60,70,1,0),COLORCYAN;
STICKLINE(青干=1,50,60,1,0),COLORGREEN;
STICKLINE(莫问=1,40,50,1,0),COLORBLUE;
STICKLINE(竞星=1,30,40,1,0),COLORMAGENTA;
STICKLINE(舍神=1,20,30,1,0),COLOR0080FF;
买入:T1<20 AND T4<20,COLOR0000FF;
STICKLINE(买入=1,0,20,1,0),COLOR0000FF;