通达信五圆弧主图及选股指标（其他）指标公式

📅 2026-09-18

核心逻辑

这是一个基于2015年6月股灾期间（6月1日至6月30日）特定高点和低点计算支撑/压力位的指标。公式通过以下步骤运作： 1. **确定基准日期**：限定在2015年6月期间（股灾发生的时间段） 2. **定位关键点位**：找出该时间段内的最高价位置(GT)和最低价位置(DT) 3. **几何计算**：基于最高价和最低价，通过数学公式（包含平方根、乘除法等）计算出一条抛物线状的支撑线(SH)和压力线(XH) 4. **预测作用**：这条曲线代表从最高点到最低点过程中的理论支撑/压力位置

买卖信号

**买入条件（XG1）**： - 股价第一次上穿支撑线SH - 且发生在DT点之前 **图形信号**： - 当出现买入信号时，K线显示为彩色柱状（从深蓝到浅蓝的渐变色） **辅助显示**： - 在中间位置显示跌幅百分比 - 在突破价位置显示"突破价：XX元"

用法

1. **适用场景**：主要针对2015年6月股灾期间的个股分析，用于判断后续反弹时的压力位 2. **操作思路**： - 观察股价是否能够突破SH线（突破价） - 突破后可能存在反弹机会 - 结合跌幅百分比判断反弹空间 3. **注意事项**：该指标是特定历史行情的回归分析，对当前行情的指导意义有限，主要用于研究历史走势或类似极端行情的参考

公式源码

A:=CURRBARSCOUNT;
HA:=IF(BETWEEN(DATE,1150601,1150630),H,-999);
T:=HHVBARS(HA,0);
TT:=BARSLAST(L=LLV(L,T+1));
T1:=BARSLAST(A=CONST(TT)+1);
T2:=BARSLAST(A=CONST(T)+1);
GT:=CONST(T2)+1;
DT:=CONST(T1)+1;
AA:=DRAWLINE(A=GT,H,A=DT,L,0);
DRAWBAND(AA,RGB(69,139,0),AA,RGB(69,139,0));
HH:=CONST(REF(L,BARSLAST(A=DT+1)));
LL:=CONST(REF(H,BARSLAST(A=GT+1)));
JJ:=HH-LL;
TJ:=Abs(GT-DT);
PT:=TJ/2+MIN(GT,DT);
PJ:=(HH+LL)/2;
LJ:=HH*LL;
BT:=2*LJ/TJ;
BJ:=LJ/JJ;
TJA:=IF(A<PT,PT-A,A-PT)*BT;
TJB:=IF(TJA<LJ,SQRT(LJ*LJ-TJA*TJA),0)/BJ;
XH:IF(DT<GT,PJ+TJB,PJ-TJB),COLORMAGENTA;
SH:IF(DT<GT,PJ-TJB,PJ+TJB),COLORMAGENTA;
XG1:=COUNT(crOSS(C,SH),T1+1)=1 AND CROSS(C,SH) AND A<DT;
TB:=A=ROUND((GT+DT)/2);
ZF:=(REF(C,T1)-REF(C,T2+1))/REF(C,T2+1)*100;
DRAWTEXT(TB,AA,VARCAT(VARCAT('跌幅：',VAR2STR(CONST(ZF),2)),'%')),COLORGREEN;
DRAWTEXT(A=DT-1,SH*1.02,VARCAT(VARCAT('突破价：',VAR2STR(SH,2)),'元')),COLORYELLOW;
STICKLINE(XG1,L,H,0,0),COLOR0088EE;
STICKLINE(XG1,CLOSE,OPEN,3,0),COLOR0055AA;
STICKLINE(XG1,CLOSE,OPEN,2.8,0),COLOR0066BB;
STICKLINE(XG1,CLOSE,OPEN,2.5,0),COLOR0077CC;
STICKLINE(XG1,CLOSE,OPEN,2.2,0),COLOR0088DD;
STICKLINE(XG1,CLOSE,OPEN,1.7,0),COLOR0099EE;
STICKLINE(XG1,CLOSE,OPEN,1.2,0),COLOR00AAFF;
STICKLINE(XG1,CLOSE,OPEN,0.7,0),COLOR00CCFF;
STICKLINE(XG1,CLOSE,OPEN,0.2,0),COLOR00FFFF;
{
选股公式:
A:=CURRBARSCOUNT;
HA:=IF(BETWEEN(DATE,1150601,1150630),H,-999);
T:=HHVBARS(HA,0);
TT:=BARSLAST(L=LLV(L,T+1));
T1:=BARSLAST(A=CONST(TT)+1);
T2:=BARSLAST(A=CONST(T)+1);
GT:=CONST(T2)+1;
DT:=CONST(T1)+1;
AA:=DRAWLINE(A=GT,H,A=DT,L,0);
HH:=CONST(REF(L,BARSLAST(A=DT+1)));
LL:=CONST(REF(H,BARSLAST(A=GT+1)));
JJ:=HH-LL;
TJ:=ABS(GT-DT);
PT:=TJ/2+MIN(GT,DT);
PJ:=(HH+LL)/2;
LJ:=HH*LL;
BT:=2*LJ/TJ;
BJ:=LJ/JJ;
TJA:=IF(A<PT,PT-A,A-PT)*BT;
TJB:=IF(TJA<LJ,SQRT(LJ*LJ-TJA*TJA),0)/BJ;
SH:=IF(DT<GT,PJ-TJB,PJ+TJB);
XG:COUNT(CROSS(C,SH),T1+1)=1 AND CROSS(C,SH) AND A<DT;
}

📖 相关推荐