核心逻辑
这是一个基于**缠论**理论的画笔指标。核心原理是： 1. **识别"笔"**：通过连续6根K线是否创新高/新低来识别基本的涨跌段落（笔） 2. **黄金柱/倍缩**：标记成交量放大1.9倍以上的"黄金柱"和缩量到0.6倍以下的"倍缩"量能异动 3. **笔的升级**：通过价格创新高/新低的程度，将笔分为5个级别（G1-G5/D1-D5），级别越高趋势越强 4. **结合KDJ过滤**：在笔的确认中使用KDJ指标来过滤假信号，提高准确性 5. **自动画线**：在确认的笔的起点和终点之间画出趋势线
买卖信号
**买入信号（向上笔）：** - G1：形成向上笔，且距上次向下笔的距离大于4根K线 - G2：G1后股价创新高 - G3：G2或向上笔初始形成且KDJ.J>100（超买） - G4：G3或向上笔形成且创前期G2高点 - G5：G4且股价创笔形成以来最高（最强买入信号） **卖出信号（向下笔）：** - D1：形成向下笔，且距上次向上笔的距离大于4根K线 - D2：D1后股价创新低 - D3：D2或向下笔初始形成且KDJ.J<0（超卖） - D4：D3或向下笔形成且创前期D2低点 - D5：D4且股价创笔形成以来最低（最强卖出信号）
用法
1. **关注G5和D5信号**：这两个是最强的买卖信号，表示趋势已经确认并延续 2. **配合黄金柱**：黄金柱（成交量放大）出现时，笔的信号可靠性更高 3. **结合画线**：黄绿色线段显示笔的走势，可直观看到支撑位和压力位 4. **仓位管理**：G1-G5信号逐渐增强，可考虑逐步加仓；D1-D5信号逐渐增强，应逐步减仓 5. **结合其他指标**：可配合MACD、均线等指标综合判断，避免假信号
公式源码
{缠论画笔}
黄金柱:=V/REF(V,1)>=1.9;
DRAWLINE(黄金柱,L,REF(黄金柱,1),REF(L,1),1),COLORYELLOW;
DRAWLINE(黄金柱,H,REF(黄金柱,1),REF(H,1),1),COLORRED;
倍缩:=V/REF(V,1)<=0.6;
DRAWLINE(倍缩,H,REF(倍缩,1),REF(H,1),1),COLOR1D7300;
HH:=REF(H,5)=HHV(H,13);
LL:=REF(L,5)=LLV(L,13);
FG01:=BACKSET(HH,6)>BACKSET(HH,5) ;
FD01:=BACKSET(LL,6)>BACKSET(LL,5) ;
FG0:=FG01 AND H=HHV(H,BARSLAST(FD01));
FD0:=FD01 AND L=LLV(L,BARSLAST(FG01));
J0:=(H+L)/2;
FGH:=REF(H,BARSLAST(FG0));
FGH1:=REF(H,BARSLAST(FG0)+1);
FGL1:=REF(L,BARSLAST(FG0)+1);
FGH2:=REF(H,BARSLAST(FG0)+2);
FGL2:=REF(L,BARSLAST(FG0)+2);
FGJ0:=REF(J0,BARSLAST(FG0));
FGL:=REF(L,BARSLAST(FG0));
FDH:=REF(H,BARSLAST(FD0));
FDL:=REF(L,BARSLAST(FD0));
FDH1:=REF(H,BARSLAST(FD0)+1);
FDL1:=REF(L,BARSLAST(FD0)+1);
FDH2:=REF(H,BARSLAST(FD0)+2);
FDL2:=REF(L,BARSLAST(FD0)+2);
FDJ0:=REF(J0,BARSLAST(FD0));
FGZH:=IF(FGL<FGL1,FGH2,FGH1);
FGZL:=IF(FGL<FGL1,FGL2,FGL1);
FDZH:=IF(FDH>FDH1,FDH2,FDH1);
FDZL:=IF(FDH>FDH1,FDL2,FDL1);
FG1:=IF(((FGL>FDH AND FGH>FDZH) OR (FGH>FDH1 AND FDH1>FDH AND FDH>FDH2)),FG0,FG0 AND FGJ0>FDH AND FGH>FDZH);
FD1:=IF(((FDH<FGL AND FDL<FGZL) OR (FDL<FGL1 AND FGL1<FGL AND FDL<FGL2)),FD0,FD0 AND FDJ0<FGL AND FDL<FGZL);
FG2:=FG1 AND H>=HHV(H,BARSLAST(FD1));
FD2:=FD1 AND L<=LLV(L,BARSLAST(FG1));
FG:=FG2 AND kdj.K>40;FD:=FD2 AND kdJ.K<60;
BK:=IF((FGL1>=FGL AND FG0) OR (FDH1<=FDH AND FD0),4,3);
G1:=FG AND BARSLAST(FD)>BK;
D1:=FD AND BARSLAST(FG)>BK;
G2:=G1 AND H>=HHV(H,BARSLAST(D1));
D2:=D1 AND L<=LLV(L,BARSLAST(G1));
G3:=G2 OR (FG0 AND KDJ.J>100);
D3:=D2 OR (FD0 AND KDJ.J<0);
G4:=G3 OR (FG0 AND REF(H,BARSLAST(FG0))>REF(H,BARSLAST(G2)) AND BARSLAST(D2)>BARSLAST(G2));
D4:=D3 OR (FD0 AND REF(L,BARSLAST(FD0))<REF(L,BARSLAST(D2)) AND BARSLAST(G2)>BARSLAST(D2));
G5:=G4 AND H=HHV(H,BARSLAST(D4));
D5:=D4 AND L=LLV(L,BARSLAST(G4));
GPB:=IF(G4,H,DRAWNULL),CIRCLEDOT,COLORYELLOW;
DPB:=IF(D4,L,DRAWNULL),CIRCLEDOT,COLORYELLOW;
NN:=G5;UU:=D5;
DRAWLINE(UU,L,NN, H,0),COLORFF00FF,LINETHICK1;
DRAWLINE(NN,H,UU, L,0),COLOR80FF00,LINETHICK1;
{涨停板}
TB:=(C-REF(C,1))/REF(C,1)*100;
STICKLINE(TB>9.9,O,C,2.5,1)COLORMAGENTA;
STICKLINE(TB<-9.9,O,C,2.5,0)COLOR1D7300;