核心逻辑
该指标是一个综合型趋势判断指标，主要基于多条指数移动平均线（EMA）的相互关系来识别市场趋势。具体原理包括： 1. **均线系统**：使用EMA(3)、EMA(8)、EMA(13)、EMA(21)、EMA(34)、EMA(55)、EMA(120)等多条均线构建完整的均线体系 2. **趋势判断**：通过短期均线上穿/下穿中期均线来判断多空趋势转换 3. **信号过滤**：结合成交量、涨跌幅、MACD、BIAS等技术指标进行信号确认 4. **颜色区分**：用不同颜色K线表示多空状态（蓝色=多头、粉色=调整、绿色=下跌）
买卖信号
**买入信号：** - **建仓**：MA9上穿MA20（金叉） - **启动**：EMA55>EMA34>EMA13，且EMA13反弹后站上均线 - **上升**：连续5日涨幅在0-5%之间，价差波动小，且股价站上EMA55 - **涨升**：涨幅>0.5%，成交量>均量0.6倍，EMA13上穿EMA55 - **出击**：EMA13>EMA34<EMA55形态下，股价回调后再次上涨 - **金叉**：EMA34上穿EMA55 - **加仓**：EMA13上穿EMA34 - **推进**：EMA13/34/55多头排列且股价同时突破三均线 **卖出信号：** - **空仓**：MA20下穿MA9（死叉） - **卖点**：涨幅<1.02%且最高价>MA5的1.12倍（滞涨信号） - **了结**：BIAS2>10且HHV最高价出现，MACD走弱
用法
1. **基础用法**：当出现"建仓"信号时买入，出现"空仓"信号时卖出 2. **综合研判**：结合多个信号（如"启动"+"金叉"+"加仓"同时出现）进行买入确认，信号越多可靠性越高 3. **趋势跟随**：K线颜色为蓝色时持有，绿色时观望 4. **风险提示**：出现"卖点"或"了结"信号时考虑减仓或止盈 5. **优化建议**：该指标信号较多，建议结合成交量和大盘走势综合判断
公式源码
A:EMA(C,21)COLORBLUE,LINETHICK3;
B:=A<REF(A,1);
IF(B-1,A,DRAWNULL)COLORRED,LINETHICK3;
AA:=EMA(C,3) > EMA(C,21);
BB:=EMA(C,3) < EMA(C,21);
CC:= EMA(C,3) > EMA(C,8);
CC1:=EMA(C,3) < EMA(C,8);
DD:=CLOSE<OPEN;
STICKLINE(AA,H,L,0,0),COLOR007FFF;
STICKLINE(AA,O,C,3,1),COLOR007FFF;
STICKLINE(AA AND DD,O,C,3,0),COLOR007FFF;
STICKLINE(BB,H,L,0,0),COLORGREEN;
STICKLINE(BB,O,C,3,1),COLORGREEN;
STICKLINE(BB AND DD,O,C,3,0),COLORGREEN;
STICKLINE(BB AND CC,H,L,0,1),COLORF00FF0;
STICKLINE(BB AND CC,O,C,3,1),COLORF00FF0;
STICKLINE(BB AND CC AND DD,O,C,3,0),COLORF00FF0;
STICKLINE(AA AND CC1,H,L,0,0),COLORBLUE;
STICKLINE(AA AND CC1,O,C,3,1),COLORBLUE;
STICKLINE(AA AND CC1 AND DD,O,C,3,0),COLORBLUE;
买线:=MA(CLOSE,9),LINETHICK2;
卖线:=MA(CLOSE,20);
BU:=crOSS(买线,卖线);
SEL:=CROSS(卖线,买线);
DRAWTEXT(BU,L-0.1,'建仓')COLORYELLOW;
DRAWTEXT(SEL,H+0.1,'空仓');
A2:=(C-REF(C,1))/REF(C,1)*100<1.02;
A3:=H>MA(C,5)*1.12;
AAA:= A2 AND A3;
DRAWTEXT(AAA,H*1.05,'卖点'),COLORWHITE;
EMA13:=EMA(C,13),COLOR0000FF,LINETHICK2;
EMA34:=EMA(C,34),COLORYELLOW;
EMA55:=EMA(C,55),COLORFF00FF;
EMA120:=EMA(C,120),COLORFFCC66;
AR1:=EMA55>EMA34 AND EMA34>EMA13;
AR2:=BARSLAST((C-EMA13)/EMA13*100<-6);
AR3:=EMA13>=REF(EMA13,2);
AR4:=COUNT(CROSS(C,EMA13),AR2)=1;
AR5:=AR1 AND AR2 AND AR3 AND AR4;
AR6:=AR5 AND FILTER(AR5,10);
DRAWTEXT(AR6,L-0.09,'启动'),COLORYELLOW;
STICKLINE(AR6,H,L,3,0),LINETHICK2,COLORYELLOW;
BR1:=COUNT(BETWEEN((C-REF(C,1))/REF(C,1)*100,0,5) ,5)=5;
BR2:=Abs((EMA13-EMA34)+(EMA34-EMA55))/C<0.2;
BR3:=C>EMA55 AND (REF(C,1)<REF(EMA55,1) OR REF(C,2)<REF(EMA55,2) OR REF(C,3)<REF(EMA55,3) OR REF(C,4)<REF(EMA55,4) OR REF(C,5)<REF(EMA55,5));
BR4:=BR1 AND BR2 AND BR3;
DRAWTEXT(BR4 AND FILTER(BR4,10),L-0.09,'上升'),COLOR00C5FF;
STICKLINE(BR4 AND FILTER(BR4,10),O,C,3,1),LINETHICK2,COLOR00C5FF;
CR1:=(C-REF(C,1))/REF(C,1)*100>0.5;
CR2:=V>MA(V,5)*0.6;
CR3:=COUNT(CROSS(EMA13,EMA55),3)=1;
CR4:=ABS(EMA34-EMA55)/EMA55<0.03;
CR5:=EMA55<=EMA120 AND EMA55>=REF(EMA55,1);
CR6:=FILTER(CR1 AND CR2 AND CR3 AND CR4 AND CR5,2);
STICKLINE(CR6,O,C,3,1),LINETHICK2,COLORF00FF0;
DRAWTEXT(CR6,L-0.09,'涨升'),COLORF00FF0;
DR1:=EMA13>EMA34 AND EMA34<EMA55;
DR2:=BARSLAST(CROSS(C,EMA55) );
DR3:=H=HHV(H,DR2);
DR4:=BARSLAST(DR3);
DR5:=COUNT(O>C AND C<REF(C,1) AND C>EMA55 AND BETWEEN((C-EMA55)/EMA55,0,0.02),DR4)=1;
DR6:=C>REF(C,1) ;
DR7:= DR1 AND DR5 AND DR6 ;
DR8:=DR7 AND FILTER(DR7 ,10);
DRAWTEXT(DR8,L-0.09,'出击'),COLORD6BA63;
ER:=BARSLAST(REF(CROSS(EMA55,EMA34),1)) AND CROSS(EMA34,EMA55);
DRAWTEXT(ER,L-0.09,'金叉'),COLOR0099FF;
FR:=BARSLAST(REF(CROSS(EMA34,EMA13),1)) AND CROSS(EMA13,EMA34);
DRAWTEXT(FR,L-0.09,'加仓'),COLORWHITE;
GR1:=BARSLAST(BETWEEN("bias.BIAS2"(6,13,24),0,5) );
GR2:=EMA13>EMA34 AND EMA34>EMA55 AND EMA13>REF(EMA13,1);
GR3:=COUNT("BIAS.BIAS2"(6,13,24)>10 AND H=HHV(H,GR1),GR1);
GR4:=H=HHV(H,GR1);
GR5:="macd.MACD"(12,26,9)<REF("MACD.MACD"(12,26,9),1);
GR6:=GR2 AND GR3 AND GR4;
GR7:=GR2 AND GR3 AND GR4 AND GR5;
DRAWTEXT(GR6 AND GR7,H+0.13,'了结'),COLOR00FF00;
HR2:=EMA13>=REF(EMA13,3) AND EMA34>=REF(EMA34,1) AND EMA55>=REF(EMA55,1) AND CROSS(C,EMA13) AND CROSS(C,EMA34) AND CROSS(C,EMA55);
DRAWTEXT(HR2 AND FILTER(HR2,10),L-0.3,'推进'),COLORFFC8FF;
STICKLINE(HR2 AND FILTER(HR2,10),O,C,3,1),LINETHICK2,COLORFFC8FF;