通达信新超跌底部吸筹+选股指标（其他）指标公式

📅 2026-10-18

核心逻辑

这是一个综合型选股指标，融合了多种技术分析方法来判断股票的潜在上涨机会。核心原理包括： 1. **吸筹判断**：通过比较短期(8日)和长期(34日)最低价区域，计算价格波动强度。当价格处于局部最低时，认为可能有主力资金吸筹。 2. **KDJ金叉**：使用经典的KDJ指标，当J线从下向上穿越K线时产生XG1信号。 3. **超跌反弹**：VAR1综合计算收盘价与6日、12日、24日均线的偏离程度，当VAR1上穿其6日均线且VAR1<-8.5时，表示股价超跌可能反弹。 4. **月周KDJ背离/同向**：同时分析月线和周线KDJ的状态，既关注周线与月线的背离（可能反转），也关注同向上涨（趋势确认）。 5. **相对强弱**：将个股与大盘指数对比，计算相对位置，找出弱于大盘但可能即将启动的股票。

买卖信号

**买入条件（XG信号，需同时满足）**： - XG1：KDJ金叉（J线上穿K线） - XG2：2日内出现过VAR1上穿VAR2且VAR1<-8.5 - XG3：3日内出现过月周KDJ背离或同向信号，且月K<20、周K<30 - 底部：相对大盘的强弱值<20%（即股价相对大盘处于250日内的底部区域） - 吸筹：DD>AA且DD<0且AA<0（长期和短期吸筹指标都为负，但长期比短期更高） **卖出信号**：公式中未明确给出卖出条件，主要用于选股和买入

用法

公式源码

Y1:=LLV(L,34);
Y2:=SMA(Abs(L-REF(L,1)),34,1);
Y3:=SMA(MAX(L-REF(L,1),0),34,2);
DD:-(EMA(IF(L<=Y1,Y2/Y3,-3),9)),STICK,COLORRED,LINETHICK1;
STICKLINE(DD<0,0,DD,2,0),COLOR00FF00;
Y11:=LLV(L,8);
Y21:=SMA(ABS(L-REF(L,1)),34,1);
Y31:=SMA(MAX(L-REF(L,1),0),34,2);
AA:-(EMA(IF(L<=Y11,Y21/Y31,-3),9)),COLORBLUE,LINETHICK1;
STICKLINE(DD>AA,DD,AA,2,0),COLORCYAN,LINETHICK1;
RSV:=(CLOSE-LLV(LOW,5))/(HHV(HIGH,5)-LLV(LOW,5))*100;
K:=SMA(RSV,3,1);
D:=SMA(K,3,1);
J:=3*K-2*D;
XG1:crOSS(J,K),NODRAW;
VAR1:=((CLOSE-MA(CLOSE,6))/MA(CLOSE,6)*200
+(CLOSE-MA(CLOSE,24))/MA(CLOSE,24)*300
+(CLOSE-MA(CLOSE,12))/MA(CLOSE,12)*100)/6;
VAR2:=MA(VAR1,6);
XG2:CROSS(VAR1,VAR2)  AND VAR1<-8.5,NODRAW;
月D:="kdj.D"(89,3,3);
周D:="kdJ.D"(27,3,3);
月K:="KDJ.K"(89,3,3);
周K:="KDJ.K"(27,3,3);
周D涨:=周D>REF(周D,1);
周D跌:=周D<REF(周D,1);
月D涨:=月D>REF(月D,1);
月D跌:=月D<REF(月D,1);
背离:=(周D涨 AND 月D跌) OR (周D跌 AND 月D涨);
同向:=周D涨 AND 月D涨 AND REF(周D跌,1) AND REF(月D跌,1) 
AND REF(周D跌,2) AND REF(月D跌,2) AND  REF(周D跌,3) AND REF(月D跌,3);
XG3:(背离 OR 同向)  AND 月K<20  AND 周K<30;
C1:=1000*C/INDEXC;
H1:=1000*H/INDEXH;
L1:=1000*L/INDEXL;
O1:=1000*O/INDEXO;
底部:(C1-LLV(L1,250))/(HHV(H1,250)-LLV(L1,250))*100<20,NODRAW;
吸筹:DD>AA  AND DD<0 AND AA<0,NODRAW;
XG:XG1  AND COUNT(XG2,2)=1  AND COUNT(XG3,3)=1 AND 底部 AND 吸筹,COLORRED,NODRAW; 
DRAWICON(XG,底部*1.05,25);
选股公式:
Y1:=LLV(L,34);
Y2:=SMA(ABS(L-REF(L,1)),34,1);
Y3:=SMA(MAX(L-REF(L,1),0),34,2);
DD:=-(EMA(IF(L<=Y1,Y2/Y3,-3),9));
Y11:=LLV(L,8);
Y21:=SMA(ABS(L-REF(L,1)),34,1);
Y31:=SMA(MAX(L-REF(L,1),0),34,2);
AA:=-(EMA(IF(L<=Y11,Y21/Y31,-3),9));
RSV:=(CLOSE-LLV(LOW,5))/(HHV(HIGH,5)-LLV(LOW,5))*100;
K:=SMA(RSV,3,1);
D:=SMA(K,3,1);
J:=3*K-2*D;
XG1:=CROSS(J,K);
VAR1:=((CLOSE-MA(CLOSE,6))/MA(CLOSE,6)*200
+(CLOSE-MA(CLOSE,24))/MA(CLOSE,24)*300
+(CLOSE-MA(CLOSE,12))/MA(CLOSE,12)*100)/6;
VAR2:=MA(VAR1,6);
XG2:=CROSS(VAR1,VAR2)  AND VAR1<-8.5;
月D:="KDJ.D"(89,3,3);
周D:="KDJ.D"(27,3,3);
月K:="KDJ.K"(89,3,3);
周K:="KDJ.K"(27,3,3);
周D涨:=周D>REF(周D,1);
周D跌:=周D<REF(周D,1);
月D涨:=月D>REF(月D,1);
月D跌:=月D<REF(月D,1);
背离:=(周D涨 AND 月D跌) OR (周D跌 AND 月D涨);
同向:=周D涨 AND 月D涨 AND REF(周D跌,1) AND REF(月D跌,1) 
AND REF(周D跌,2) AND REF(月D跌,2) AND  REF(周D跌,3) AND REF(月D跌,3);
XG3:=(背离 OR 同向)  AND 月K<20  AND 周K<30;
C1:=1000*C/INDEXC;
H1:=1000*H/INDEXH;
L1:=1000*L/INDEXL;
O1:=1000*O/INDEXO;
底部:=(C1-LLV(L1,250))/(HHV(H1,250)-LLV(L1,250))*100<20;
吸筹:=DD>AA  AND DD<0 AND AA<0;
XG:XG1  AND COUNT(XG2,2)=1  AND COUNT(XG3,3)=1 AND 底部 AND 吸筹;

📖 相关推荐