核心逻辑
这是一个**自适应双均线系统**，核心特点是均线周期会根据股价波动自动调整。具体原理： 1. **自适应周期计算**：首先计算过去P天（默认64天）内的最高价和最低价，然后计算最高点到最低点之间的时间间隔（天数），这个间隔作为均线周期 2. **双均线组合**： - JX：长期均线，周期=高低点间隔天数 - DX：短期均线，周期=间隔天数的0.25倍 3. **MACD辅助判断**：用EMA(12,26)构建MACD指标，用类似K线的方式显示红绿色，便于直观判断趋势金叉/死叉区域
买卖信号
1. **买入信号**：DX均线上穿JX均线（短期均线上穿长期均线） 2. **卖出信号**：JX均线上穿DX均线（长期均线上穿短期均线） 3. **趋势辅助**： - MACD红柱区域（金叉）：表示趋势安全，可安心持有 - MACD绿柱区域（死叉）：表示趋势有变，需要了结
用法
1. **参数调整**：P默认为64，可根据个股或指数特性调整。上证指数用默认参数时，高低点间隔约34天，均线会自动调整为34天 2. **看盘要点**： - 关注均线交叉信号，买卖点的判断 - 配合MACD红绿柱判断趋势方向 - 红K线持有，绿K线警惕 3. **辅助显示**：公式还显示了最高价、最低价、25%、50%、75%等关键价位线，以及涨停板（蓝色）和跌停板（蓝色）的标记
公式源码
将百分线与自适应双均线巧妙结合。方便实用。
p为可调参数，默认为64，可以根据具体
个股与指数自己设置。举例如下：
上证指数在默认参数下，可知如下信息
低点与高点相距34天，故而均线jx自动
调整为34天均线，而均线dx为0.25倍周期
的短线均线。此两条均线组合为双均线系统
可以完美诠释均线交叉的内在特性。颇具实战
参考意义图中k线乃macd指标定义。
红色表示macd金叉区域，趋势安全，安心持有。
绿色表示macd死叉区域，趋势有变。注意了结。
P:=64;
DRAWTEXT_FIX(ISLASTBAR,0.65,0.8,0,HYBLOCK),COLOR00FF00;
DRAWTEXT_FIX(ISLASTBAR,0.75,0.8,0,DYBLOCK),COLOR00FFFF;
DRAWTEXT_FIX(ISLASTBAR,0.65,0.9,0,GNBLOCK),COLORYELLOW;
{以上为显示所属板块，地域，概念等}
EE:=CURRBARSCOUNT<=P;
高:=HHV(H,P);
低:=LLV(L,P);
相对:(C-低)/(高-低)*100,NODRAW,COLORFFFF00;
区间:(高-低)/低*100,NODRAW,COLORWHITE;
天:=CONST(高)COLORYELLOW;
地:=CONST(低)COLOR00FF00;
强:=CONST(高*3/4+低*1/4);
中:=CONST(高*1/2+低*1/2);
弱:=CONST(高*1/4+低*3/4);
STICKLINE(EE,天,天,5,0),COLORYELLOW;
STICKLINE(EE,地,地,5,0),COLOR00FF00;
STICKLINE(EE,强,强,1,0),COLORFFFF00;
STICKLINE(EE,中,中,5,0),COLORWHITE;
STICKLINE(EE,弱,弱,1,0),COLOR0099FF;
DT:=H=天;
DL:=L=地;
高T:=BARSLAST(DT)+1;
低T:=BARSLAST(DL)+1;
STICKLINE(EE AND DT,天,地,0,0),COLORRED;
STICKLINE(EE AND DL,天,地,0,0),COLOR00FF00;
间隔:Abs(高T-低T),COLOR00FF00,NODRAW;
PT:=CONST(间隔);
JX:MA(C,PT),COLORWHITE,LINETHICK2;
DX:MA(C,PT*0.25),COLORYELLOW,LINETHICK1;
AB:=EMA(C,12);
BB:=EMA(C,26);
AO:=(AB-BB);
XH:=EMA(AO,9);
AC:=2*(AO-XH);
KK:=IF(AC>0, 5,-5);
STICKLINE(KK=5,H,L,0.2,0),COLORRED;
STICKLINE(KK=5 AND C>=O,C,O,3,1),COLORRED;
STICKLINE(KK=5 AND C<O,C,O,3,0),COLORRED;
STICKLINE(KK=-5,H,L,0.2,0),COLOR00CC00;
STICKLINE(KK=-5 AND C>=O,C,O,3,1),COLOR00CC00;
STICKLINE(KK=-5 AND C<O,C,O,3,0),COLOR00CC00;
ZDF:=(C-REF(C,1))/REF(C,1)*100;
STICKLINE(ZDF>9.9,O,C,1,0),COLOR0099FF;
STICKLINE(ZDF<-9.9,O,C,1,0),COLORBLUE;
{以上为macd指标定义k线，红色表示金叉区域，绿色为死叉}
DRAWICON(crOSS(DX,JX),JX,1);
DRAWICON(CROSS(JX,DX),JX,2);
IF(JX>REF(JX,1),JX,DRAWNULL),COLORRED,LINETHICK2;
IF(DX<REF(DX,1),DX,DRAWNULL),COLOR00FF00,LINETHICK1;
DRAWNUMBER(ISLASTBAR,天,天),COLORYELLOW;
DRAWNUMBER(ISLASTBAR,地,地),COLOR00FF00;
DRAWNUMBER(ISLASTBAR,强,强),COLORFFFF00;
DRAWNUMBER(ISLASTBAR,中,中),COLORWHITE;
DRAWNUMBER(ISLASTBAR,弱,弱),COLOR0099FF;